Преобразование нескольких строк в одну строку

Question

У меня есть много файлов XML со многими событиями. Любое событие имеют некоторые тег:

<v8e:Event> 
    <v8e:Level>Information</v8e:Level> 
    <v8e:Date>2015-12-22T16:18:17</v8e:Date> 
    <v8e:ApplicationName>1CV8</v8e:ApplicationName> 
</v8e:Event> 
<v8e:Event> 
    <v8e:Level>Information</v8e:Level> 
    <v8e:Date>2015-12-23T16:18:17</v8e:Date> 
    <v8e:ApplicationName>1CV28</v8e:ApplicationName> 
</v8e:Event> 

Я хочу, чтобы преобразовать эти стриктуры для этого:

Information, 2015-12-22T16:18:17, 1CV8 
Information, 2015-12-23T16:18:17, 1CV28 

Я знаю, как удалить XML-тег, но я не не знаю, как конкатенация другой строки в одном.

@echo от SETLOCAL EnableDelayedExpansion

(for /F "delims=" %%a in ('findstr /I /L "<v8e:Level> <v8e:Date> <v8e:ApplicationName>" *.xml') do (
    set "line=%%a" 
    set "line=!line:*<v8e:Level>=!" 
    set "line=!line:*<v8e:Date>=!" 
    set "line=!line:*<v8e:ApplicationName>=!" 
    for /F "delims=<" %%b in ("!line!") do echo %%b 
)) > 111.txt 

Как reuslt у меня есть:

Information 
2015-12-22T16:18:17 
1CV8 
Information 
2015-12-23T16:18:17 
1CV28 

И я также хочу, имя выходного файла же, как входной файл. Возможно, кто-то может остановить меня, чтобы решить эту проблему?

Answer 1

Вы близки:

@echo off 
setlocal EnableDelayedExpansion 

set "output=" 
set "fields=0" 
for /F "delims=" %%a in ('findstr /I /L "<v8e:Level> <v8e:Date> <v8e:ApplicationName>" *.xml') do (
    set "line=%%a" 
    set "line=!line:*<v8e:Level>=!" 
    set "line=!line:*<v8e:Date>=!" 
    set "line=!line:*<v8e:ApplicationName>=!" 
    for /F "delims=<" %%b in ("!line!") do set "line=%%b" 
    set "output=!output!!line!, " 
    set /A fields+=1 
    if !fields! equ 3 (
     set "file=%%a" 
     for /F "delims=:" %%b in ("!file!") do echo !output:~0,-2!>> "%%~Nb.txt" 
     set "output=" 
     set "fields=0" 
    ) 
) 

Однако это так, как я хотел бы сделать это:

@echo off 
setlocal EnableDelayedExpansion 

for %%f in (*.xml) do (

    set "output=" 
    set "fields=0" 
    (for /F "tokens=3 delims=<>" %%a in ('findstr /I /L "<v8e:Level> <v8e:Date> <v8e:ApplicationName>" "%%f"') do (
     set "output=!output!%%a, " 
     set /A fields+=1 
     if !fields! equ 3 (
     echo !output:~0,-2! 
     set "output=" 
     set "fields=0" 
    ) 
    )) > "%%~Nf.txt" 

)