VBScript не работает в зависимости от веб-сервера

Question

У меня очень странная проблема с VBScript: он отлично работает в зависимости от сервера, на котором находится веб-сайт.

У меня одно и то же веб-приложение на двух серверах с IIS 7.5. На каждом сервере код точно то же самое.

VBScript выполняет некоторые строки Excel и обновляет некоторую информацию в веб-приложении. Проблема возникает при обновлении этой информации. В одном из серверов, нет никаких проблем, но в других, я получаю ошибку ниже:

Как работает сценарий, как это будет делать, я думаю, нет никакой ошибки синтаксиса

код метание ошибка:

With objIE 
    If (testing) Then 
     .Navigate URLtesting 
    Else 
     .Navigate URL 
     WScript.Sleep 2000 
    End If 

    WaitWebLoad() 
    .document.getElementById(user).Value = userScript 
    .document.getElementById(password).Value = passwordScript 
    .document.getElementById(logInButton).Click() 
    WaitWebLoad() 
    .document.getElementByID(loretoLink).Click() 
    WaitWebLoad() 
    .document.getElementByID(updatePLLink).Click() 
    WaitWebLoad() 

    Do 
     lastRow = activeSheet.Cells(rowIndex, columnPL_ID).Value 
     dateAssociated = activeSheet.Cells(rowIndex, columnArrivalDate).Value 
     concesion = activeSheet.Cells(rowIndex, columnConcesion).Value 
     If lastRow <> "" Then 
      .document.getElementByID(searchPL_TB).Value = lastRow 
      .document.getElementByID(searchPL_Button).Click() 
      WaitWebLoad() 
      If (Not (.document.getElementByID(errorLookingPL)) Is Nothing Or Not (.document.getElementByID(noSearchResult) Is Nothing)) Then 
       'PL not found 
       recordsNotFound = recordsNotFound + 1 
       WriteOpenFileText(logFilePath), (Now & vbTab & "***PL not found: " & lastRow & " - [" & dateAssociated & "]" & " - " & concesion & vbCrLf) 
      Else ... 

номер строки 295:

If (Not (.document.getElementByID(errorLookingPL)) is Nothing Or Not (.document.getElementByID(noSearchResult) is Nothing)) Then 

WaitWebLoad код функция:

Function WaitWebLoad() 
    Dim timer 
    timer = 0 

    With objIE 
     Do While .Busy 
      If timer < timerWebLoad Then 
       WScript.Sleep 100 
       timer = 100 
      Else 
       'Error loading the web 
       objExcel.Workbooks.close 
       objExcel.quit 
       objIE.quit 
       DeleteFile(pathTemp) 
       endScriptStamp = Now 

       WScript.Echo("Error." & vbCrLf & "Total runtime is: " & DateDiff("s", startScriptStamp, endScriptStamp) & " seconds.") 
       WScript.quit 
      End If 
     Loop 
    End With 
End Function 

Я думаю, проблема в том, что сценарий, при запуске сервера, где ошибка происходит, теряет objIE объекта, но я не знаю, почему это становится потерянный только на одном из серверов.

Answer 1

getElementById метод возвращает первый объект с тем же ID атрибутом как указанное значение, или нулем если id не может быть найден. Ссылка: .NET Framework и Document Object Model (DOM).
С другой стороны, Is operator сравнивает два объекта ссылочные переменные и Null не является объектом; это означает, что переменная не содержит достоверных данных.
Кроме того, при использовании в VBScript, getElementById метод может поднять 800A01A8 (= десятичную -2146827864) ошибка Microsoft VBScript выполнения: Object required при неправильном использовании: например, как вы не можете писать Set objAny = Null!

Вот обходной путь:

On Error Resume Next            ' enable error handling 
    Set oerrorLookingPL = .document.getElementByID(errorLookingPL) ' try 
    If Err.Number <> 0 Then Set oerrorLookingPL = Nothing   ' an error occurred? 
    Err.Clear 
    If Vartype(oerrorLookingPL) = 1 Then Set oerrorLookingPL = Nothing ' Null => Nothing 
    Set onoSearchResult = .document.getElementByID(noSearchResult) 
    If Err.Number <> 0 Then Set onoSearchResult = Nothing 
    Err.Clear 
    If Vartype(onoSearchResult) = 1 Then Set onoSearchResult = Nothing 
On Error Goto 0             ' disable error handling 
If (Not (oerrorLookingPL Is Nothing) Or Not (onoSearchResult Is Nothing)) Then 

Я не могу рекомендовать глобальное использование On Error Resume Next как If condition Then … заявления всегда оценивает данный condition в True, если происходит ошибка при выполнении при оценке его, смотрите следующий пример:

On Error Resume Next 
' show Variant subtype information about Null and Nothing 
Wscript.Echo VarType(Null) & " Null " & TypeName(Null) 
Wscript.Echo VarType(Nothing) & " Nothing " & TypeName(Nothing) 
' all conditions as well as their negations are evaluated to `True` 
if  (Null = Nothing) then Wscript.Echo "  Null = Nothing" 
if NOT (Null = Nothing) then Wscript.Echo "not (Null = Nothing)" 
if  (Null is Nothing) then Wscript.Echo "  Null is Nothing" 
if NOT (Null is Nothing) then Wscript.Echo "not (Null is Nothing)" 
' show runtime error 
On Error GoTo 0 
if  (Null is Nothing) then Wscript.Echo "  Null is Nothing" 

И Null = Nothing, и Null is Nothing условия оцениваются до True, а также их отрицания!

==> cscript D:\VB_scripts\SO\37563820.vbs 
1 Null Null 
9 Nothing Nothing 
    Null = Nothing 
not (Null = Nothing) 
    Null is Nothing 
NOT (Null is Nothing) 
==> D:\VB_scripts\SO\37563820.vbs(12, 1) Microsoft VBScript runtime error: Object required