Удаление строки из ряда строк, созданных Союзами в VBA

Question

Кажется, что это должно быть просто выполнить, но для жизни я не могу найти правильную команду или трюк.

В моем макросе, я систематически генерировать диапазон строк, используя союз между хребтом и новой строки в цикле:

Set DesiredRange = Union(DesiredRange, ActiveSheet.Cells(Val(ParsedText(Count)), 1).EntireRow) 

Однако, для того, чтобы этот союз работать, я должен сначала установить DesiredRange, равный некоторому диапазону, чтобы Союз не выходил из системы.

Проблема, с которой я столкнулась, состоит в том, что мне нужно выделить некоторые номера строк, но строки выбираются из текстового поля userform, которое позволяет пользователю вводить все, что они хотят (я закодирован в управлении ошибками, чтобы пройденные значения действительны), поэтому они могут гипотетически сделать первое значение (и, тем самым, то, что я использую для инициализации диапазона), - это строка, в которую включена строка.

Я надеюсь, что у кого-то здесь может быть решение, позволяющее мне выполнить все операции, а затем удалить эту первую добавленную строку из диапазона, если она находится в пределах категории (от 1 до 7). Если нет, я думаю, что у меня, возможно, есть работа (но часть меня задает этот вопрос больше для образования, чем решение проблемы)

Спасибо!

Answer 1

Я думаю, что вам нужна функция, например Range.Except, для дополнения Range.Intersect и Range.Union, но AFAIK не встраивается в VBA, и вам придется ее самостоятельно закодировать. Что-то вроде следующего выполнит то, что вы хотите, и автоматически исключите нежелательные строки из Union. Переменная strRowsToExclude, вероятно, будет передан в метод из вашей формы:

Sub Test() 

    Dim rngTarget As Range 
    Dim strRowsToExclude As String 
    Dim varRowsToExclude As Variant 
    Dim intCounter1 As Integer 
    Dim intCounter2 As Integer 
    Dim blnDoNotAdd As Boolean 

    Set rngTarget = Nothing 
    strRowsToExclude = "1,4,45,87,88,99" 
    varRowsToExclude = Split(strRowsToExclude, ",") 

    For intCounter1 = 1 To 100 
     blnDoNotAdd = False 
     For intCounter2 = 0 To UBound(varRowsToExclude) 
      If intCounter1 = Val(varRowsToExclude(intCounter2)) Then 
       blnDoNotAdd = True 
      End If 
     Next intCounter2 
     If blnDoNotAdd = False Then 
      If rngTarget Is Nothing Then 
       Set rngTarget = Sheet1.Cells(intCounter1, 1).EntireRow 
      Else 
       Set rngTarget = Union(rngTarget, Sheet1.Cells(intCounter1, 1).EntireRow) 
      End If 
     End If 
    Next intCounter1 

    rngTarget.Select 

End Sub 

Answer 2

вы могли бы сделать, как следует:

Option Explicit 

Sub main() 
    Dim desiredRng As Range, forbiddenRows As Range, cell As Range 
    Dim rowsStrng As String 
    Dim i As Long 

    With ActiveSheet 
     Set forbiddenRows = .Range("1:1, 3:5, 7:7, 9:11") '<~~ set forbidden rows, you can use multiple rows sintax    
     For i = 1 To 10 '<~~ this is your "Union" loop, 
      ' do stuff to get to following line 
      Set cell = .Cells(Val(ParsedText(Count)), 1) 
      If Intersect(cell, forbiddenRows) Is Nothing Then rowsStrng = rowsStrng & cell.Row & ":" & cell.Row & "," '<~~ add row index only if not forbidden 
     Next i 
     If rowsStrng <> "" Then Set desiredRng = .Range(Left(rowsStrng, Len(rowsStrng) - 1)) 
    End With 
End Sub 

Answer 3

Чтобы развернуть на комментарий Рори:

Dim DesiredRange As Range, rng As Range 

'...in your loop 
Set rng = ActiveSheet.Cells(Val(ParsedText(Count)), 1).EntireRow 
If DesiredRange Is Nothing Then 
    Set DesiredRange = rng 
Else 
    Set DesiredRange = Application.Union(DesiredRange, rng) 
End If