Generic xslt, который преобразует структуру xml в список html

Question

Мне нужен общий xslt, который преобразует xml в список html.

Пример XML-фрагмент:

<person> 
    <firstname>A</firstname> 
    <lastname>B</lastname> 
    <address> 
    <city>C</city> 
    <street>S</street> 
    </address> 
</person> 

Вывод должен быть

<ul> 
    <li>person 
     <ul> 
      <li>firstname: A</li> 
      <li>lastname: B</li> 
      <li>address 
      <ul> 
       <li>city: C</li> 
       <li>street: S</li> 
      </ul> 
     </ul> 
    </li> 
</ul> 

генерируется источник XML во время выполнения не всегда будет иметь эту структуру. Таким образом, имена тегов могут быть разными. Поэтому xslt должен быть общим.

Answer 1

попробовать что-то вроде:

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:strip-space elements="*"/> 
    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
     <ul> 
      <xsl:apply-templates select="*"/> 
     </ul> 
    </xsl:template> 

    <xsl:template match="*[*]"> 
     <li> 
      <xsl:value-of select="name()"/> 
      <ul> 
       <xsl:apply-templates select="*"/> 
      </ul> 
     </li> 
    </xsl:template> 

    <xsl:template match="*[not(*)]"> 
     <li> 
      <xsl:value-of select="concat(name(), ': ', .)"/> 
     </li> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

Как насчет:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/"> 
    <ul> 
     <xsl:apply-templates/> 
    </ul> 
</xsl:template> 

<xsl:template match="*"> 
    <li> 
     <xsl:value-of select="name()" /> 
     <xsl:if test="text()"> 
      <xsl:text>: </xsl:text> 
      <xsl:apply-templates select="text()" /> 
     </xsl:if> 
     <xsl:if test="*"> 
      <ul> 
       <xsl:apply-templates/> 
      </ul> 
     </xsl:if> 
    </li> 
</xsl:template> 

</xsl:stylesheet>