Проверьте, когда часть MovieClip покидает сцену

Question

Я создаю игру с перетаскиванием, используя AS3, я хочу проверить, не находится ли за пределами Movieclip вне экрана, чтобы перемещать вид сзади и позволить пользователю выбирать, где бросить его.

I can not test, если учетные данные MovieClip больше, чем на этапе (scaleMode = NO_SCALE) Ширина/Высота, потому что есть часть сцены, которая скрыта за окном браузера.

Это тот же аспект, что и MOUSE_LEAVE, на этот раз он должен быть для MovieClips, я попытался увидеть код за MOUSE_LEAVE, но я не смог его достичь.

Thank you.

Основной класс

[SWF(width='800', height='800',backgroundColor='#CC99FF', frameRate='60')] 
public class DragTest extends Sprite 
{ 
    public function DragTest() 
    { 
     addChild(new World(this)); 

     this.stage.scaleMode = "noScale"; 
     this.stage.align = "TL"; 

     this.graphics.lineStyle(5,0x555555,0.5); 
     this.graphics.drawRect(0,0,800,800); 
    } 
} 

МИР КЛАСС

public class World extends Container // Container from my SWC 
{ 
    private var _display:Sprite; 
    private var _dragPt:Point; 
    private var _dragedObject:MovieClip; 

    public function World(display:Sprite) 
    { 
     super(); 

     _display = display; 

     myMC.addEventListener(MouseEvent.MOUSE_DOWN, onPickUp, false, 0, true); 

     display.stage.addEventListener(MouseEvent.MOUSE_UP, onDrop, false, 0, true); 
     display.stage.addEventListener(Event.MOUSE_LEAVE, onMouseLeave, false, 0, true); 
    } 

    protected function onMouseLeave(event:Event):void 
    { 
     trace("Mouse Is Leaving The Stage"); 

    } 

    protected function onDrop(e:MouseEvent):void 
    { 
     _display.stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMoveObject); 

    } 

    private function onPickUp(e:MouseEvent) 
    { 
     _dragedObject = e.currentTarget as MovieClip; 

     _display.stage.addEventListener(MouseEvent.MOUSE_MOVE, onMoveObject, false, 0, true); 
    } 

    protected function onMoveObject(e:MouseEvent):void 
    { 
     var point:Point = new Point(_display.stage.mouseX, _display.stage.mouseY); 

      (_dragedObject as MovieClip).x = point.x; 
      (_dragedObject as MovieClip).y = point.y;   
    } 
} 

Ниже приведен пример: Simple Code

Answer 1

Самый простой подход, вероятно, будет использовать getBounds(stage) и сравнить с stageWidth и stageHeight:

var bounds:Rectangle = _draggedObject.getBounds(stage); 
if (bounds.left < 0) { 
    // left part of object is off-screen 
} else if (bounds.right > stage.stageWidth) { 
    // right part of object is off-screen 
} 
if (bounds.top < 0) { 
    // top part of object is offscreen 
} else if (bounds.bottom > stage.stageHeight) { 
    // bottom part of object is off-screen 
} 

Вы можете переместить display в каждом из этих случаев.

Answer 2

Вы можете попытаться создать невидимую зону, которая немного меньше вашей сцены.

Итак, вы можете добавить событие MOUSE_LEAVE в зону, и когда ваша мышь покинет эту зону, вы сможете делать то, что хотите.

Check the example here.