Как предотвратить функции CATx от оценки выражения

Question

При вызове функции CATT() с помощью% sysfunc существует ли способ остановить ее от оценки выражения?

В приведенном примере код:

%let date=10-13-2015; 
%put %sysfunc(catt(The date Is:,&date)); 

Я хотел бы, чтобы вернуться:

The date Is:10-13-2015 

Поскольку 10-13-2015 просто текстовая строка. Но вместо того, чтобы CATT() видит дефис, как знак вычитания и оценивает его как числовое выражение, возвращая:

The date Is:-2018 

Я попытался макрос процитировать, но ничего не изменится, я полагаю, потому что мне нужно как-то скрыть значения из CATT(). Кажется, что если какой-либо аргумент CATT выглядит как выражение, он будет рассматриваться как таковой.

Другой пример:

%let value=2 and 3; 
%put %sysfunc(catt(The value Is:,&value)); 
The value Is:1 

Answer 1

При условии, что вы можете сделать это, просто удалить запятую - нет никакой необходимости, чтобы отделить его в отдельный параметр (если вы не используете catx(), а не catt():

%let date=10-13-2015; 
%put %sysfunc(catt(The date Is: &date)); 

Лично я считаю, что лучший способ работы - сохранить дату как значение даты SAS, а затем использовать второй (необязательный) параметр %sysfunc для применения форматирования. Это обеспечивает лучшую гибкость.

%let date = %sysfunc(mdy(10,13,2015)); 
%put The date Is: %sysfunc(sum(&date),mmddyyd10.); 

Если вы настойчивы на оригинальном подходе и использовании catx(), то я не знаю, как это сделать точно. Самое близкое, что я мог получить, это вставить фрагмент текста, чтобы он не мог интерпретироваться как выражение, а затем удалять этот текст после использования tranwrd. Довольно, некрасиво, и это оставляет пространство:

%let date=10-13-2015; 
%let tmp=%sysfunc(catx(#, The date Is: , UNIQUE_STRING_TO_REMOVE&date)); 
%let want=%sysfunc(tranwrd(&tmp, UNIQUE_STRING_TO_REMOVE,)); 

%put &want; 

Выдает:

The date Is:# 10-13-2015 

Я также попробовал все комбинации макро цитировал, и просмотрел весь список функций SAS и не мог видеть любой другой жизнеспособные варианты.

Answer 2

Проблема с% SYSFUNC(), оценивающая аргументы, не ограничена рядом функций CAT(). Любая функция, которая принимает числовые значения, приведет к попытке SAS оценить предоставленное выражение.

Это может быть полезной функцией. Например:

%let start_dt=10OCT2012 ; 
%put %sysfunc(putn("&start_dt"d +1,date9)); 

Вам не нужно использовать функции CAT() для работы с макропеременными. Просто увеличьте значения рядом друг с другом, а «объединены».

%let date=10-13-2015; 
%put The date Is:&date; 

Если вы хотите создать макрос, который работает как функция CATX(), то это также не сложно.

%macro catx /parmbuff ; 
%local dlm return i ; 
%if %length(&syspbuff) > 2 %then %do; 
    %let syspbuff = %qsubstr(&syspbuff,2,%length(&syspbuff)-2); 
    %let dlm=%qscan(&syspbuff,1,%str(,),q); 
    %let return=%qscan(&syspbuff,2,%str(,),q); 
    %do i=3 %to %sysfunc(countw(&syspbuff,%str(,),q)); 
    %let return=&return.&dlm.%qscan(&syspbuff,&i,%str(,),q); 
    %end; 
%end; 
&return. 
%mend catx; 

%put %catx(|,a,b,c); 
a|b|c 
%put "%catx(",",a,b,c,d)"; 
"a","b","c","d" 

Answer 3

Я, к сожалению, не вижу легкого пути вокруг этого.Я вижу, что вы могли бы теоретически передать это через функцию FCMP, хотя с FCMP не позволяет аргументы истинных переменных, то есть далеко не идеально, но ...

proc fcmp outlib=work.funcs.funcs; 
    function catme(delim $, in_string $) $; 
    length _result $1024; 
    length _new_delim $1; 
    _new_delim = scan(in_string,1,delim); 
    do _i = 1 to countc(in_string,delim); 
     _result = catx(_new_delim, _result, scan(in_string,_i+1,delim)); 
    end; 
    return(_result); 
    endfunc; 
quit; 

options cmplib=work.funcs; 

%let date=10-13-2015; 
%put %sysfunc(catme(|,:|The date Is| &date.)); 

Или добавить кавычки в аргументе а затем удалите их после CATx.

%sysfunc(dequote(%sysfunc(catt(.... ,"&date.")))) 

Все беспорядочно.

Answer 4

Чуть менее безумный макро функция стиль без dosubl:

%macro catx() /parmbuff; 
%local rc dlm i params OUTSTR QWORD outstr; 
%let SYSPBUFF = %qsubstr(&SYSPBUFF,2,%length(&SYSPBUFF)-2); 
%let dlm = %qscan(&SYSPBUFF,1,%str(,)); 
%let params = %qsubstr(&SYSPBUFF,%index(&SYSPBUFF,%str(,))+1); 

%let i = 1; 
%let QWORD = %scan(&PARAMS,&i,%str(,)); 
%let OUTSTR = &QWORD; 
%do %while(&QWORD ne); 
    %let i = %eval(&i + 1); 
    %let QWORD = %scan(&PARAMS,&i,%str(,)); 
    %if &QWORD ne %then %let OUTSTR = &OUTSTR.&DLM.&QWORD; 
%end; 

%unquote(&OUTSTR) 
%mend catx; 

%put %catx(%str(),abc,10 - 1 + 2,def); 

Несколько более безумный, но, по-видимому работает вариант - использовать %sysfunc(dosubl(...)) и много макро логики создать макрос функции в стиле, который принимает входной сигнал в том же как %sysfunc(catx(...)), но заставляет catx обрабатывать весь ввод как текст, цитируя его и вызывая его на шаге данных.

%macro catxt() /parmbuff; 
%local rc dlm i params QPARAMS QWORD outstr; 
%let SYSPBUFF = %qsubstr(&SYSPBUFF,2,%length(&SYSPBUFF)-2); 
%let dlm = %qscan(&SYSPBUFF,1,%str(,)); 
%let params = %qsubstr(&SYSPBUFF,%index(&SYSPBUFF,%str(,))+1); 

%let i = 1; 
%let QWORD = "%scan(&PARAMS,&i,%str(,))"; 
%let QPARAMS = &QWORD; 
%do %while(&QWORD ne ""); 
    %let i = %eval(&i + 1); 
    %let QWORD = "%scan(&PARAMS,&i,%str(,))"; 
    %if &QWORD ne "" %then %let QPARAMS = &QPARAMS,&QWORD; 
%end; 

%let rc = %sysfunc(dosubl(%str(
    data _null_; 
     call symput("OUTSTR",catx("&dlm",%unquote(&QPARAMS))); 
    run; 
))); 

&OUTSTR 
%mend catxt; 

%put %catxt(%str(),abc,10 - 1 + 2,def); 

Хотя это использует шаг данных для выполнения catx, dosubl позволяет все это будет работать в любом месте, где можно было нормально использовать %sysfunc(catx(...)).