Windows Batch - Как получить внешний IP-адрес в переменной пакетного файла

Question

Я делаю программу, которая проверяет, является ли IP-адрес пользователя определенным IP-адресом.

В настоящее время я создал успешную внутреннюю версию IP:

@echo off 
set userIp=192.168.90.100 
for /f "tokens=4 delims= " %%i in ('route print ^| find " 0.0.0.0"') do set localIp=%%i 
for /f "delims=[] tokens=2" %%a in ('ping %computername% -4 -n 1 ^| findstr "["') do set thisip=%%a 
goto :Check 

:Check 
if %localIp%==%userIp% goto :Good 
if %thisip%==%userIp% goto :Good 
goto :Bad 

И я пытаюсь сделать то же самое, что работает с внешними IP-адресами.

Я исследовал онлайн, и вот что я получил до сих пор.

@echo off 
for /f "tokens=2 delims=:" %%a IN ('nslookup myip.opendns.com. resolver1.opendns.com ^| findstr /IC:"Address"') do if /i %%a=="10.11.12.13" goto :Good 
goto :Bad 

Мне нужна помощь, как это исправить.

С уважением, djmrminer.

Answer 1

С чистыми серийными/уже имеющимися инструментами:

@Echo off 
for /f "tokens=2 delims=: " %%A in (
    'nslookup myip.opendns.com. resolver1.opendns.com 2^>NUL^|find "Address:"' 
) Do set ExtIP=%%A 
Echo External IP is : %ExtIP% 

Reference

Еще один с PowerShell:

@Echo off 
For /f %%A in (
    'powershell -command "(Invoke-Webrequest "http://api.ipify.org").content"' 
) Do Set ExtIP=%%A 
Echo External IP is : %ExtIP% 

Answer 2

Сначала кажется, что есть . после первого .com.

Во-вторых при использовании команды с просто google.com и echo %a я получаю следующее:

" xx.xx.xx.x"без котировки и с двумя ведущими пробелами!

Значит, ваш, если будет никогда не быть правдой!

Измените его на следующее: if "%%a"==" xx.xx.xx.x" Goto:good, и все должно быть хорошо.

Answer 3

Чтобы получить публичный IP без дополнительного разбора сделать это:

завиток "http://api.ipify.org"

EDIT:

Эта версия является более надежным по языковых версиях Windows:

for /f "tokens=3 delims== " %%A in (' 
nslookup -debug myip.opendns.com. resolver1.opendns.com 2^>NUL^|findstr /C:"internet address" 
') do set "ext_ip=%%A"