Скрыть длинное сообщение об авторском праве в верхней части всех файлов

Question

У нас есть сообщения об авторских правах длиной 15 строк в верхней части всех файлов исходного кода.

Когда я их открываю в emacs, это отнимает много ценного пространства.
Есть ли способ заставить emacs всегда скрывать определенное сообщение, но оставить его в файле?

Answer 1

Вы можете написать функцию, которая сужает ваш буфер ко всем, кроме первых 15 строк.

(defun hide-copyright-note() 
    "Narrows the current buffer so that the first 15 lines are 
hidden." 
    (interactive) 
    (save-excursion 
    (goto-char (point-min)) 
    (forward-line 15) 
    (narrow-to-region (point) (point-max)))) 

Тогда все, что вам нужно сделать, это убедиться, что эта функция вызывается для каждого файла, содержащего примечание об авторских правах. Это можно сделать, добавив крючок, предпочтительно в основной режим вашего файла. Например, вы могли бы добавить приведенное выше определение функции и следующую строку в файл .emacs:

(add-hook 'c-mode-hook 'hide-copyright-note) 

Это вызов функции «скрыть авторские_права_на_документацию-нотная всякий раз, когда вы открываете файл C.

На практике вы, вероятно, захотите сделать вашу функцию крюка более умной, либо проверив, что на самом деле существует скрытая записка об авторских правах, либо запустив скрыть авторское право, только если файл находится в определенном каталоге и т. Д.

Например, придерживаться примере C, вы можете вставить следующий тест в приведенной выше функции:

(defun hide-copyright-note() 
    "Narrows the current buffer so that the first 15 lines are 
hidden." 
    (interactive) 
    (when (copyright-message-p) 
    (save-excursion 
     (goto-char (point-min)) 
     (forward-line 15) 
     (narrow-to-region (point) (point-max))))) 

(defun copyright-message-p() 
    "Returns t when the current buffer starts with a Copyright 
note inside a C-style comment" 
    (save-excursion 
    (goto-char (point-min)) 
    (looking-at "\\s */\\*\\(:?\\s \\|\\*\\)*Copyright\\b"))) 

Как для других относятся:

Когда я их открываю в emacs, это отнимает много ценного пространства.

... или вы можете просто прокрутить вниз. Для достижения этой цели автоматически, мы могли бы использовать следующую функцию вместо hide-copyright-note:

(defun scroll-on-copyright() 
    "Scrolls down to the 16th line when the current buffer starts 
with a copyright note." 
    (interactive) 
    (when (copyright-message-p) 
    (goto-char (point-min)) 
    (beginning-of-line 16) 
    (recenter 0))) 

Однако, почему я рекомендовал первый вариант является то, что если вы просто прокрутите вниз автоматически, то всякий раз, когда вы прыгаете на начало буфера (M-<) вам придется прокручивать вниз вручную. Эта проблема не возникает с сужением решения.

Answer 2

Посмотрите на folding-mode. В принципе, все, что вам нужно, это способ идентифицировать детали, которые нужно сложить, а затем использовать folding-top-mark и folding-bottom-mark, чтобы отметить их. К сожалению, с помощью кода EMISS elisp есть хаки, поэтому вы должны легко найти код, который можно адаптировать.

Answer 3

Вы можете использовать hideshow minor mode, который является стандартным встроенным пакетом, который имеет обобщенную команду под названием hs-hide-initial-comment-block, которая будет делать то, что вы хотите, не зная, как долго находится верхний раздел комментариев. Вы можете добавить его в режиме крюк любого языка, но вот пример использования C:

(add-hook 'c-mode-common-hook 'hs-minor-mode t) 
(add-hook 'c-mode-common-hook 'hs-hide-initial-comment-block t) 

Примечания, он не скрывает, специально только авторских прав, но полный первоначальный комментарий блок, который может скрыть полезным документация.