Является ли значение ячейки в столбце B в столбце A? (LibreOffice-Calc)

Question

• Колонка A имеет список отсортирован-нисходящую Топ-250 фильмов некоторых Bum в, в следующем формате: Апокалипсис сегодня (1979)
• Колонка B имеет упорядоченный список Мой Топ- 100, в том же формате.
• Оба списка были скопированы и вставлены в текстовый документ Notepad, чтобы подтвердить, что они похожи на простой текст ASCI - никаких дополнительных пробелов в конце - и т. Д. - и затем вставляются обратно в LibreofficeCalc.

Мне нужна функция для столбца C, которая показывает любое из моих фильмов (B), которое он НЕ перечисляет в (A).

код Psudo:

• С1 = Значение ячейки в В1 - это где-нибудь в A1: A8000? Если нет - поместите значение B1 в C1, в противном случае оставьте пустым.
• C2 = значение ячейки в B2 - это где-нибудь в A1: A8000? Если нет - положите значение B2 в C2, в противном случае оставьте пустым.
• Etc.

Я искал и нашел эти функции - ни один из которых работают, по какой-либо причине. Я изменил их до 8000 в качестве верхнего диапазона, который, как я думаю, никогда не подниму.

=IF(ISERROR(MATCH(B1,$A$1:$A$8000,0))=1,B1,"") 
=IFERROR(MATCH(B1;$A$1:$A$8000;0);"") 
=IFNA(VLOOKUP($B1;$A$1:$A$8000;1;0);"") 
=IF(ISNA(VLOOKUP($B1;$A$1:$A$8000;1;0));"";VLOOKUP($B1;$A$1:$A$8000;1;0)) 
=IF(ISNA(VLOOKUP($B1,$A$1:$A$8000,1,0)),"",VLOOKUP($B1,$A$1:$A$8000,1,0)) 
=VLOOKUP(B1,$A$1:$A$8000,1,) 
=MATCH($B1;$A$1:$A$999;0) 

Я бы предпочел, чтобы это была одна функция соты, а не VBA.

Я действительно решил это вернуться в 2001 году, используя Excel. Трюк тогда был, мне пришлось отредактировать ячейку и использовать Ctrl-Shift-Enter для создания «динамического массива», поэтому функция была заключена в скобки в {} фигурных скобках. Но теперь я использую последний LibreOffice Calc и не могу получить правильный синтаксис @# $ #.

спасибо !!

Редактировать ПРИМЕЧАНИЕ: тестирование номерами «A» и «00001» дает очень разные результаты. Значения должны выглядеть в обоих столбцах:

• Алиса (1988)
• Barfly (1987)
• Бестолковые (1995)
• т.д.

Answer 1

OK Я проверил они находятся в открытом офисе со следующими результатами: -

=IF(ISERROR(MATCH(B1,$A$1:$A$8000,0))=1,B1,"") 

Дает ошибку 508 be потому что запятые должны меняться на точки с запятой.

**=IF(ISERROR(MATCH(B1;$A$1:$A$8000;0))=1;B1;"")** 

в порядке.

=IFERROR(MATCH(B1;$A$1:$A$8000;0);"") 

Дает #Name? потому что IFERROR не признается.

=IFNA(VLOOKUP($B1;$A$1:$A$8000;1;0);"") 

Дает #Name? потому что IFNA не распознается.

=IF(ISNA(VLOOKUP($B1;$A$1:$A$8000;1;0));"";VLOOKUP($B1;$A$1:$A$8000;1;0)) 

Работы, но дает противоположный результат.

**=IF(ISNA(VLOOKUP($B1;$A$1:$A$8000;1;0));B1;"")** 

будет в порядке.

=IF(ISNA(VLOOKUP($B1,$A$1:$A$8000,1,0)),"",VLOOKUP($B1,$A$1:$A$8000,1,0)) 

Запятые

=VLOOKUP(B1,$A$1:$A$8000,1,) 

запятые

=MATCH($B1;$A$1:$A$999;0) 

Работает, но только дает положение матча.

Вероятно, самый простой способ сделать это: -

**=IF(COUNTIF(A$1:A$8000;B1);"";B1)** 

К сожалению, это, кажется, что строки с кронштейнами в дают ложные совпадения в Libre/Open Office. Вы можете получить вокруг него подстановкой я думаю

=IF(COUNTIF(SUBSTITUTE(SUBSTITUTE(A$1:A$10;"(";"<");")";">");SUBSTITUTE(SUBSTITUTE(B1;"(";"<");")";">"));"";B1) 

введена как формула массива и копируется (а не потянул) вниз или, конечно, глобального редактирования всех скобок :-(.

Теперь, когда я знаю причину этого, благодаря @Lyrl, есть еще вариант отключив регулярные выражения, как предложено или вы могли бы избежать скобки: -

=IF(COUNTIF(A$2:A$11;SUBSTITUTE(SUBSTITUTE(B2;"(";"\(");")";"\)"));"";B2) 

См документации по Regex в Open Office here

Answer 2

Это должно сделать это,

=IF(ISNUMBER(MATCH(B1,$A$1:$A$8000,0)),"",B1) 

Answer 3

Испытано формула

=IF(ISNA(MATCH(B1,$A$1:$A$8000,0))=TRUE(),B1,"")