Активность диска в Applescript

Question

Как я могу опросить активность диска в Applescript? Проверьте, читается ли диск X, записывается или простаивает каждые N секунд и что-то делает.

Answer 1

В целом, опрос менее эффективен, чем уведомление, когда что-то происходит. Кроме того, если вы проверяете, читает ли что-то с диска, вы, вероятно, сами будете обращаться к указанному диску, возможно, влияя на то, что вы пытаетесь наблюдать.

С 10.5 OSX включает в себя что-то, что называется инфраструктурой событий файловой системы, которая предоставляет подробные уведомления об изменениях в файловой системе. Проблема в вашем случае состоит в том, что это только Objective-C. Об этом API есть Apple documentation.

К счастью, есть и команда call method AppleScript. Это позволяет работать с объектами Objective-C из AppleScript. Вот documentation.

У меня нет опыта ни с одним из них, поэтому ссылки на документацию. Надеюсь, вам это нужно.

Answer 2

Вы можете периодически запускать команду терминала iostat. Вы должны проанализировать результаты в форме, которую вы можете переварить.

Если вы знаете достаточно о различных инструментах командной строки UNIX, я бы предложил iostat передать выходные данные awk или sed, чтобы извлечь только необходимую информацию.

Answer 3

Вы должны действительно посмотреть на Dtrace. Он обладает способностью делать подобные вещи.

#!/usr/sbin/dtrace -s 
/* 
* bitesize.d - analyse disk I/O size by process. 
*    Written using DTrace (Solaris 10 build 63). 
* 
* This produces a report for the size of disk events caused by 
* processes. These are the disk events sent by the block I/O driver. 
* 
* If applications must use the disks, we generally prefer they do so 
* sequentially with large I/O sizes. 
* 
* 15-Jun-2005, ver 1.00 
* 
* USAGE: bitesize.d # wait several seconds, then hit Ctrl-C 
* 
* FIELDS: 
*  PID process ID 
*  CMD command and argument list 
*  value size in bytes 
*  count number of I/O operations 
* 
* NOTES: 
* The application may be requesting smaller sized operations, which 
* are being rounded up to the nearest sector size or UFS block size. 
* To analyse what the application is requesting, DTraceToolkit programs 
* such as Proc/fddist may help. 
* 
* SEE ALSO: seeksize.d, iosnoop 
* 
* Standard Disclaimer: This is freeware, use at your own risk. 
* 
* 31-Mar-2004 Brendan Gregg Created this, build 51. 
* 10-Oct-2004  "  " Rewrote to use the io provider, build 63. 
*/ 

#pragma D option quiet 

/* 
* Print header 
*/ 
dtrace:::BEGIN 
{ 
    printf("Sampling... Hit Ctrl-C to end.\n"); 
} 

/* 
* Process io start 
*/ 
io:::start 
{ 
    /* fetch details */ 
    this->size = args[0]->b_bcount; 
    cmd = (string)curpsinfo->pr_psargs; 

    /* store details */ 
    @Size[pid,cmd] = quantize(this->size); 
} 

/* 
* Print final report 
*/ 
dtrace:::END 
{ 
    printf("\n%8s %s\n","PID","CMD"); 
    printa("%8d %s\n%@d\n",@Size); 
} 

От here.

Для запуска используйте

sudo dtrace -s bitsize.d 

Answer 4

Как Porkchop D. Clown упоминалось, вы можете использовать IOSTAT. Вы можете использовать команду:

iostat -c 50 -w 5 

Который будет запускать iostat 50 раз каждые 5 секунд.