AS3 Случайное изображение из XML - Never Repeat

Question

Я создаю баннерное объявление во флеше, которое показывает 3 случайных изображения из файла XML после загрузки страниц. Моя проблема в том, что она будет иногда повторяться. Я включил свой код, какие-нибудь советы?

---

var pHeight:Number = 84; 
var pWidth:Number = 120; 


var listLoader:URLLoader = new URLLoader(new URLRequest("www.example.com/example.xml")); 
var picLoader:Loader = new Loader(); 

listLoader.addEventListener(Event.COMPLETE, gotList); 

function gotList(evt:Event):void { 
    var xmlData:XML = XML(listLoader.data); 
    var numImages:Number = xmlData.picture.length(); 
    var stImage:String = xmlData.picture[Math.floor(numImages*Math.random())].toString(); 

    picLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotPic); 
    picLoader.load(new URLRequest(stImage)); 

    listLoader.removeEventListener(Event.COMPLETE, gotList); 
} 

function gotPic(evt:Event):void { 
    var thisBmp:Bitmap = Bitmap(evt.target.content); 
    thisBmp.x = 0; 
    thisBmp.y = 0; 
    var thisWidth:Number = thisBmp.width; 
    var thisHeight:Number = thisBmp.height; 

    thisBmp.scaleX = pWidth/thisWidth; 
    thisBmp.scaleY = pHeight/thisHeight; 
    addChild(thisBmp); 

    picLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, gotPic); 
} 

Answer 1

Как уже упоминалось в комментариях, вы хотите, чтобы переместить загрузку XML из MovieClip в основной класс/документ (или, если вы работаете на временной шкале, вы можете поставьте его там ... Я не потворствую этому поведению, я просто хочу быть в состоянии ответить на ваш вопрос независимо от вашего метода).

После того, как вы загрузили в XML один раз, вы можете захватить изображения оттуда, поместить их в Array, и сделать случайный вид на него:

var images:Array = []; 
for each(var imgObj:XML in xml.img){ 
    images.push(imgObj.toString()); 
} 
images.sort(function(a:Object,b:Object):int{return Math.random() > .5 ? -1 : 1}) 

Вы, вероятно, нужно изменить приведенный выше код для соответствия формату вашего XML.

Следующая вещь, которую вы хотите сделать, это создать публичный метод на вашем MovieClip, что позволит вам установить изображение для этого клипа:

function setPic(stImage:String):void { 
    picLoader = new Loader(); 
    picLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, gotPic); 
    picLoader.load(new URLRequest(stImage)); 
    addChild(picLoader); 
} 

Наконец, вы можете использовать этот метод setPic установить изображение на каждом экземпляре вашей MovieCilp:

for(var i:int = 0; i < images.length; i++) 
{ 
    this["mc"+(i+1)].setPic(images[i]); 
} 

Это предполагает определенное именование ваших MovieClip экземпляров (mc1, mc2 и т.д.)