ColdFusion & Java (библиотека docx4j)

Question

Мне нужно выполнить манипуляции с docx (найти/заменить на заполнителях и установить/снять флажки). Поскольку ColdFusion 10 хорошо интегрируется с Java, я решил попробовать использовать библиотеку docx4j Java, которая в основном имитирует OpenXML SDK (платформу .net).

У меня есть docx4j JAR внутри пользовательской папки, которую я имею установку в моем Application.cfc через JavaSettings (новые в CF10, и я попытался его с другими БАНКИ и он работает):

<cfcomponent output="false"> 

    <cfset this.javaSettings = 
     {LoadPaths = ["/myJava/lib"], loadColdFusionClassPath = true, reloadOnChange= true, 
     watchInterval = 100, watchExtensions = "jar,class,xml"} /> 

</cfcomponent> 

сейчас Я пытаюсь использовать этот пример: https://github.com/plutext/docx4j/blob/master/src/main/java/org/docx4j/samples/VariableReplace.java

Но попытка вызвать WordprocessingMLPackage терпит неудачу с функцией CreateObject() о том, что конкретный класс не существует:

<cfset docObj = createObject("java","org.docx4j.openpackaging.packages.WordprocessingMLPackage") /> 

Любые идеи? Я не являюсь Java-парнем, но там не так много вариантов для манипуляций с docx.

Answer 1

Вы пробовали установить loadColdFusionClassPath = false вместо true? Возможно, есть конфликт с некоторыми из JAR, которые отправляют w/CF.

Answer 2

Хорошо. Похоже, у меня все работает. Мне просто нужно выяснить, как сделать поиск/замену, и все остальное, что я хочу сделать в документе docx. Вот мой код так далеко, чтобы показать вам, ребята, что это выглядит, как он работает (убедитесь, что ваш Application.cfc похож на оригинальный пост, если вы на CF10):

<cfscript> 

    docPackageObj = createObject("java","org.docx4j.openpackaging.packages.WordprocessingMLPackage").init(); 
    docObj = createObject("java","org.docx4j.openpackaging.parts.WordprocessingML.MainDocumentPart").init(); 
    xmlUtilObj = createObject("java","org.docx4j.XmlUtils").init(); 
    wmlDocObj = createObject("java","org.docx4j.wml.Document").init(); 
    saveToZipFile = createObject("java","org.docx4j.openpackaging.io.SaveToZipFile").init(docPackageObj); 

    strFilePath = getDirectoryFromPath(getCurrentTemplatePath()) & "testDoc.docx"; 

    wordMLPackage = 
     docPackageObj.load(createObject("java","java.io.File").init(javaCast("string",strFilePath))); 

    documentPart = wordMLPackage.getMainDocumentPart(); 

    // unmarshallFromTemplate requires string input  
    strXml = xmlUtilObj.marshaltoString(documentPart.getJaxbElement(),true); 

    writeDump(var="#strXml#"); 

</cfscript> 

Теперь, знает кто-нибудь, как литые структуры в ColdFusion в хэшмапы (или коллекции вообще)? Я думаю, что структуры в CF фактически используются. Vector, тогда как hashmaps используются. HashMap. Все примеры, которые я вижу с docx4j, который демонстрирует найти/заменить в заполнители использовать этот:

HashMap<String, String> mappings = new HashMap<String, String>(); 
mappings.put("colour", "green"); 
mappings.put("icecream", "chocolate"); 

Answer 3

(на самом деле не новый ответ, но это слишком много кода для комментариев ..)

Вот полный код для docx4j VariableReplace.java пример

<cfscript> 
    saveToDisk = true; 
    inputFilePath = ExpandPath("./docx4j/sample-docs/word/unmarshallFromTemplateExample.docx"); 
    outputFilePath = ExpandPath("./OUT_VariableReplace.docx"); 

    inputFile = createObject("java", "java.io.File").init(inputFilePath); 
    wordMLPackage = createObject("java","org.docx4j.openpackaging.packages.WordprocessingMLPackage").load(inputFile); 
    documentPart = wordMLPackage.getMainDocumentPart(); 

    XmlUtils = createObject("java","org.docx4j.XmlUtils"); 
    xmlString = XmlUtils.marshaltoString(documentPart.getJaxbElement(),true); 

    mappings = createObject("java", "java.util.HashMap").init(); 
    mappings["colour"] = "green"; 
    mappings["icecream"] = "chocolate"; 
    obj = XmlUtils.unmarshallFromTemplate(xmlString , mappings); 
    documentPart.setJaxbElement(obj); 

    if (saveToDisk) { 
     saveToZipFile = createObject("java","org.docx4j.openpackaging.io.SaveToZipFile").init(wordMLPackage); 
     SaveToZipFile.save(outputFilePath); 
    } 
    else { 
     WriteDump(XmlUtils.marshaltoString(documentPart.getJaxbElement(), true, true)); 
    } 
</cfscript>