XSLT разделительная строка для создания опции выбора

Я пытаюсь создать выпадающий элемент в XSLT, где значение и метка разделены двоеточием (:) и символом новой строки для следующего элемента.XSLT разделительная строка для создания опции выбора

У меня есть простой xml; (Система генерировала)

<root> 
<item> 
test1 : Test 1 
test2 : Test 2 
test3 : Test 3 
</item> 
</root>

потом разделить его на:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 


    <xsl:template match="text/text()" name="tokenize"> 

     <xsl:param name="text" select="."/> 
     <xsl:param name="separator" select="'&#x0a;'"/> 

     <xsl:choose> 
      <xsl:when test="not(contains($text, $separator))"> 
       <item><xsl:value-of select="normalize-space($text)"/></item> 
      </xsl:when> 
      <xsl:otherwise> 
       <item> 
        <xsl:value-of select="normalize-space(substring-before($text, $separator))"/> 
       </item> 

       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="text" select="substring-after($text, $separator)"/> 
       </xsl:call-template> 

      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet>

Выход:

<root> 
<text> 
<item>test1 : Test 1</item> 
<item>test2 : Test 2</item> 
<item>test3 : Test 3</item> 
</text> 
</root>

Тогда я не знаю, что дальше? Можно ли создать второй шаблон для создания html select?

<select> 
<option value="test1">Test 1</option> 
<option value="test2">Test 2</option> 
<option value="test3">Test 3</option> 
</select>

Пожалуйста helppppp ....: '(

источник

2016-07-04 mrrsb

Ну, если вы измените таблицу стилей что-то вроде:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="/root"> 
    <html> 
     <body> 
      <xsl:apply-templates/> 
     </body> 
    </html> 
</xsl:template> 

<xsl:template match="item"> 
    <select> 
     <xsl:call-template name="tokenize"> 
      <xsl:with-param name="text" select="."/> 
     </xsl:call-template> 
    </select> 
</xsl:template> 

<xsl:template name="tokenize"> 
    <xsl:param name="text"/> 
    <xsl:param name="delimiter" select="'&#10;'"/> 
     <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" /> 
     <xsl:if test="$token"> 
      <option value="{substring-before($token, ' : ')}"> 
       <xsl:value-of select="substring-after($token, ' : ')"/> 
      </option> 
     </xsl:if> 
     <xsl:if test="contains($text, $delimiter)"> 
      <!-- recursive call --> 
      <xsl:call-template name="tokenize"> 
       <xsl:with-param name="text" select="substring-after($text, $delimiter)"/> 
      </xsl:call-template> 
     </xsl:if> 
</xsl:template> 

</xsl:stylesheet>

вы получите:

<html> 
    <body> 
     <select> 
     <option value="test1">Test 1</option> 
     <option value="test2">Test 2</option> 
     <option value="test3">Test 3</option> 
     </select> 
    </body> 
</html>

источник

2016-07-04 05:40:37

Вау! это быстро! Ты спасаешь мой день сэр! Престижность! – mrrsb

XSLT разделительная строка для создания опции выбора

ответ

Смежные вопросы