Получение данных из таблицы SQL в Delphi

Question

У меня есть форма, которая должна отображать и отображать данные из базы данных MYSQL.
SQL-код, который я написал, отлично работает, поскольку я попытался выполнить его в MYSQL.

Я также использовал аналогичный формат кода для одного в моей форме, в другой форме, для извлечения и отображения данных SQL. Код отлично работает в другой форме.
Однако мой код для этой формы, похоже, не принимает/не отображает данные из таблицы SQL.

Это фрагмент кода, который будет написан для события OnShow формы.

procedure TfrmEditBooking.FormShow(Sender: TObject); 
var 
    CustName: string; 
begin 
    if SelectedID > 0 then 
    begin 
    with frmBookingData.ADOQuery1 do 
    begin 
     Open;  
     SQL.Clear; 
     SQL.Add('SELECT Name, Surname ' + 
       'FROM customers_main ' + 
       'WHERE customers_main.idcustomers_main ' + 
       'IN ' + 
       '(SELECT bookings_main.customers_main_idcustomers_main ' + 
       'FROM bookings_main ' + 
       'WHERE bookings_main.idbookings_main = ' + IntToStr(SelectedID) + ')'); 
     ExecSQL; 
     CustName := FieldByName('Surname').AsString + ' ' + FieldByName('Name').AsString; 
     Label1.Caption := CustName; 
     Close; 
    end; 
    end; 
end; 

Answer 1

Один использует «ExecSQL», когда один не ожидает получить курсор в наборе данных (другими словами, используйте «ExecSQL» с «обновления», «вставки» и «удалить» заявления, но не с " Выбрать').

Вы должны заменить команду «execsql» на «open» ... и удалить «open» перед «sql.clear».

Не используйте подзапрос, если вы должны использовать соединение.

Я думаю, что ваш код должен выглядеть следующим образом

procedure TfrmEditBooking.FormShow(Sender: TObject); 
begin 
if SelectedID > 0 then 
    with frmBookingData.ADOQuery1 do 
    begin 
    SQL.Clear; 
    SQL.Add ('SELECT Name, Surname '); 
    sql.add ('FROM customers_main inner join bookings_main'); 
    sql.add ('on customers_main.idcustomers_main = ');  
    sql.add ('bookings_main.customers_main_idcustomers_main'); 
    sql.add ('where bookings_main.idbookings_main = :p1'); 
    sql.params[0].asinteger:= SelectedID; 
    open; 
    Label1.Caption := fieldbyname ('name').asstring + ' ' + 
         fieldbyname ('surname').asstring; 
    Close; 
    end; 
end; 

Answer 2

Чтобы получить это работает, вы должны изменить его на

procedure TfrmEditBooking.FormShow(Sender: TObject); 
var 
    CustName: string; 
begin 
    if SelectedID > 0 then 
    begin 
     with frmBookingData.ADOQuery1 do 
     begin 
      Close; // close first 
      SQL.Clear; 
      SQL.Add(
      'SELECT Name, Surname '+ 
      'FROM customers_main '+ 
      'WHERE customers_main.idcustomers_main '+ 
      'IN '+ 
      '(SELECT bookings_main.customers_main_idcustomers_main '+ 
      'FROM bookings_main '+ 
      'WHERE bookings_main.idbookings_main = '+IntToStr(SelectedID)+')'); 
      Open; // open the query 
      if not Eof then 
      CustName := FieldByName('Surname').AsString+' '+FieldByName('Name').AsString 
      else 
      CustName := 'not found'; 
      Close; // close when finished 
     end; 
     Label1.Caption := CustName; 
    end; 
end; 

Но вы должны получить некоторые (негативные) побочные эффекты, если frmBookingData.ADOQuery1 уже используется для чего-то другого