Вложенные cfloops с меньшим количеством записей, чем внешний контур, вызывают ошибку «индекс массива вне диапазона»

Question

Мне очень любопытно, почему это происходит. Я столкнулся с этим два раза сейчас, и после тонны поискового запроса/так, я не нашел причин, по которым я действительно понимаю. Суть ее:

Запрос 1: selectContent (6 записей; нет заготовки/нули и т.д.)

Запрос 2: selectPricing (5 записей; нет заготовки/нули и т.д.)

Выход:

<cfloop query="selectContent"> 
    <section> 
     #selectContent.h2# 
     <cfif selectContent.id eq 3> 
      <cfloop query="selectPricing" group="groupCol"> 
       <table class="pricing"> 
       <thead> 
        <tr> 
         <th>#description#</th> 
         <th>Price</th> 
        </tr> 
       </thead> 
       <tbody> 
        <cfloop> 
        <tr> 
         <td>#selectPricing.description#</td> 
         <td>#selectPricing.price#</td> 
        </tr> 
        </cfloop> 
       </tbody> 
       </table> 
      </cfloop> 
     </cfif> 
     #selectContent.content# 
    </section> 
</cfloop> 

Это даст следующее сообщение об ошибке: индекс массива вне диапазона: 5

ошибка возникает только когда второй д uery имеет меньше записей, чем первое. По сути, это похоже на то, что первый cfloop берет на себя итерацию цикла из этой второй, и это вызывает проблему, но также, только если у вас есть этот третий сгруппированный cfloop. Весь внутренний cfloop работает, как и в источнике.

Я придумал два способа решения этой проблемы:

• сделать это с cfoutput/группой, но это относительно уродливо, как это означает, что много закрытия cfoutputs из других частей страницы.
• вставьте cfbreak на этом третьем cfloop, если currentRow соответствует номеру записи.

Итак, два вопроса:

• Почему это даже происходит?

• Должен ли я использовать совершенно другой подход здесь (факт, что поиск в googling/so'ing не находит других с этой проблемой, несомненно, подразумевает, что ...)?

EDIT Я подал это как ColdFusion ошибка на основе обратной связи Адам Камерона ниже. Bug #3820049

Answer 1

Молодцы, вы нашли ошибку в CF. Я могу повторить его (PS ... it'd've было здорово, если бы вы включили некоторые выборочные данные спаси меня, чтобы сделать это!)

Работа вокруг прямо вперед, хотя:

<cfscript> 
selectContent = queryNew("h2,id,content", "varchar,integer,varchar", [ 
    ["one", 1, "content.1"], 
    ["two", 2, "content.2"], 
    ["three", 3, "content.3"], 
    ["four", 4, "content.4"], 
    ["five", 5, "content.5"], 
    ["six", 6, "content.6"], 
    ["seven", 7, "content.7"] 
]); 

selectPricing = queryNew("groupCol,description,price", "varchar,varchar,varchar", [ 
    ["groupCol.1", "description.1", "1.11"], 
    ["groupCol.2", "description.2", "2.22"], 
    ["groupCol.2", "description.3", "3.33"], 
    ["groupCol.3", "description.4", "4.44"], 
    ["groupCol.3", "description.5", "5.55"], 
    ["groupCol.3", "description.6", "6.66"] 
]); 

</cfscript> 
<cfloop query="selectContent"> 
    <section> 
     <cfoutput>#selectContent.h2#</cfoutput> 
     <cfif selectContent.id eq 3> 
      <cfoutput query="selectPricing" group="groupCol"> 
       <table class="pricing"> 
       <thead> 
        <tr> 
         <th>#description#</th> 
         <th>Price</th> 
        </tr> 
       </thead> 
       <tbody> 
        <cfoutput> 
        <tr> 
         <td>#description#</td> 
         <td>#price#</td> 
        </tr> 
        </cfoutput> 
       </tbody> 
       </table> 
      </cfoutput> 
     </cfif> 
     <cfoutput>#selectContent.content#</cfoutput> 
    </section> 
</cfloop> 

Обратите внимание, как я использовал <cfoutput> для выполнения внутреннего цикла.

Это серьезная ошибка в ColdFusion (10 и 11), и вы должны поднять его на их bug base (если вы делаете, сообщить номер билета/URL назад здесь, чтобы мы могли голосовать на нем)