Код Delphi/ASM несовместим с 64-битным?

Question

У меня есть пример исходного кода для OpenGL, я хотел скомпилировать 64-битную версию (используя Delphi XE2), но есть некоторый код ASM, который не удается скомпилировать, и я ничего не знаю об ASM. Вот код ниже, и я поставил два сообщения об ошибках на линиях, которые терпят неудачу ...

// Copy a pixel from source to dest and Swap the RGB color values 
procedure CopySwapPixel(const Source, Destination: Pointer); 
asm 
    push ebx //[DCC Error]: E2116 Invalid combination of opcode and operands 
    mov bl,[eax+0] 
    mov bh,[eax+1] 
    mov [edx+2],bl 
    mov [edx+1],bh 
    mov bl,[eax+2] 
    mov bh,[eax+3] 
    mov [edx+0],bl 
    mov [edx+3],bh 
    pop ebx //[DCC Error]: E2116 Invalid combination of opcode and operands 
end; 

Answer 1

Эта процедура меняет порядок байтов ABGR в ARGB и наоборот.
В 32-х этот код должен делать всю работу:

mov ecx, [eax] //ABGR from src 
bswap ecx  //RGBA 
ror ecx, 8  //ARGB 
mov [edx], ecx //to dest 

Правильный код X64 является

mov ecx, [rcx] //ABGR from src 
bswap ecx  //RGBA 
ror ecx, 8  //ARGB 
mov [rdx], ecx //to dest 

Еще один вариант - сделать чистый Pascal версии, которая изменяет порядок байтов в виде массива:- 2103 (обмен 0-го и 2-го байтов).

procedure Swp(const Source, Destination: Pointer); 
var 
    s, d: PByteArray; 
begin 
    s := PByteArray(Source); 
    d := PByteArray(Destination); 
    d[0] := s[2]; 
    d[1] := s[1]; 
    d[2] := s[0]; 
    d[3] := s[3]; 
end; 

Answer 2

У 64-разрядного бита есть разные названия для регистров указателей, и передается разница. Первые четыре параметра встроенные функции на ассемблере передаются через RCX, RDX, R8 и R9 соответственно

EBX -> RBX 
EAX -> RAX 
EDX -> RDX 

попробовать это

procedure CopySwapPixel(const Source, Destination: Pointer); 
{$IFDEF CPUX64} 
asm 
    mov al,[rcx+0] 
    mov ah,[rcx+1] 
    mov [rdx+2],al 
    mov [rdx+1],ah 
    mov al,[rcx+2] 
    mov ah,[rcx+3] 
    mov [rdx+0],al 
    mov [rdx+3],ah 
end; 
{$ELSE} 
asm 
    push ebx //[DCC Error]: E2116 Invalid combination of opcode and operands 
    mov bl,[eax+0] 
    mov bh,[eax+1] 
    mov [edx+2],bl 
    mov [edx+1],bh 
    mov bl,[eax+2] 
    mov bh,[eax+3] 
    mov [edx+0],bl 
    mov [edx+3],bh 
    pop ebx //[DCC Error]: E2116 Invalid combination of opcode and operands 
end; 
{$ENDIF}