Что делает после печати в Perl?

Question

Я новичок в Perl. Знайте немного C хотя. Я наткнулся на этот фрагмент в одном из наших классных нот:

$STUFF="c:/scripts/stuff.txt"; 

open STUFF or die "Cannot open $STUFF for read :$!"; 

print "Line $. is : $_" while (<STUFF>); 

Почему while после print заявления? Что оно делает?

Answer 1

Это то же самое, как

while (<STUFF>) { 
    print "Line $. is : $_"; 
} 

Она написана так, как это происходит потому, что это проще и компактнее. Это, в целом, Perl's _(in) известная форма «модификатор выражения» для условностей и циклов.

Answer 2

же как

while (<STUFF>) { print "Line $. is : $_"; } 

Answer 3

Следующие фрагменты точно эквивалентными, просто разные способы написать то же самое:

print "Line $. is : $_" while (<STUFF>); 

while (<STUFF>) { 
    print "Line $. is : $_"; 
} 

Что это делает каждая итерация цикла, Perl читает один строка текста из файла STUFF и помещает его в специальную переменную $_ (это то, что делают угловые скобки). Затем тело линий печатает цикл вроде:

Line 1 is : test 
Line 2 is : file

Специальная переменная $. является линия номер последней строки, прочитанной из файла, и $_ является содержимое этой линии, задается оператором угол кронштейна.

Answer 4

После того, как печать была напечатана, сделайте линию прочитанной почти как обычный английский. Он также делает упор на печать вместо времени. И вам не нужны фигурные скобки: { ... }

Можно также использовать, если и если, например,

print "Debug: foobar=$foobar\n" if $DEBUG; 

print "Load file...\n" unless $QUIET; 

Answer 5

Обратите внимание, что while оператор может следовать только тело цикла, если это один вкладыш. Если тело цикла работает по нескольким строкам, то перед ним должен стоять while.

Answer 6

Другие ответы объяснили форму модификатора оператора цикла while. Однако здесь есть много другой магии. В частности, сценарий основывается на трех специальных переменных Perl. Два из них ($_ и $!) очень распространены; другой ($.) достаточно распространен. Но они все знают.

Когда вы запускаете while <$fh> на открытую файловую дескриптор, Perl автоматически проходит через файл по строкам, пока не достигнет EOF. Внутри каждого цикла текущая строка устанавливается на $_, если вы ничего не делаете. Таким образом, эти две такие же:

while (<$fh>) { # something } 
while (defined($_ = <$fh>)) { # something } 

См perldoc perlop, в разделе операторов ввода/вывода. (Некоторые люди находят это слишком магическим, поэтому вместо этого они используют while (my $line = <$fh>).Это дает вам $line для каждой строки, а не $_, что является более ясным именем переменной, но для этого требуется больше ввода. Каждому принадлежит.)

$! содержит значение системной ошибки (если установлено). См. Раздел perldoc perlvar, раздел о $OS_ERROR, чтобы узнать, как и когда его использовать.

$. содержит номер строки. См. perldoc perlvar, раздел на $NR. Эта переменная может быть удивительно сложной. Он не обязательно будет содержать номер строки файла, который вы сейчас читаете. Пример:

#!/usr/bin/env perl 
use strict; 
use warnings; 

while (<>) { 
    print "$ARGV: $.\n"; 
} 

Если вы сохраните это как lines и запустить его как perl lines file1 file2 file3, то Perl будет считать строки прямо через file1, file2 и file3. Вы можете видеть, что Perl знает, какой файл он читает (он находится в $ ARGV, имена файлов будут правильными), но он не автоматически переводит нумерацию строк в конце каждого файла. Я упоминаю об этом, так как я немного походил на это поведение несколько раз, пока не получил его через мой (толстый) череп. Вы можете сбросить нумерацию для отслеживания отдельных файлов таким образом:

#!/usr/bin/env perl 
use strict; 
use warnings; 

while (<>) { 
    print "$ARGV: $.\n"; 
} 
continue { 
    close ARGV if eof; 
} 

Вы должны также проверить strict и warnings прагм и посмотреть на новой, три-аргументе форме open. Я только заметил, что вы «unknown (google)», что означает, что вы, вероятно, никогда не вернетесь. Наверное, по крайней мере, у меня была практика набора текста на день.

Answer 7

Я взял на себя смелость переписать свой фрагмент, как я.

Ниже моего предлагаемого кода галерея изгоев менее оптимальных методов, которые вы можете увидеть в дикой природе.

use strict; 
use warnings; 

my $stuff_path = 'c:/scripts/stuff.txt'; 

open (my $stuff, '<', $stuff_path) 
    or die "Cannot open'$stuff_path' for read : $!\n"; 

# My preferred method to loop over a file line by line: 
# while loop with explicit variable 
while(my $line = <$stuff>) { 
    print "Line $. is : $line\n"; 
} 

Другие способы, которые вы можете видеть. Каждый из них может быть заменен циклом while в моем примере выше.

# while statement modifier 
# - OK, but less clear than explicit code above. 
print "Line $. is : $_" while <$stuff>; 

# while loop 
# - OK, but if I am operating on $_ explicitly, I prefer to use an explicit variable. 
while(<$stuff>) { 
    print "Line $. is : $_"; 
} 

# for statement modifier 
# - inefficient 
# - loads whole file into memory 
print "Line $. is : $_" for <$stuff>; 

# for loop - inefficient 
# - loads whole file into memory; 
for(<$stuff>) { 
    print "Line $. is : $_\n"; 
} 

# for loop with explicit variable 
# - inefficient 
# - loads whole file into memory; 
for my $line (<$stuff>) { 
    print "Line $. is : $line\n"; 
} 

# Exotica - 

# map and print 
# - inefficient 
# - loads whole file into memory 
# - stores complete output in memory 
print map "Line $. is : $_\n", <$stuff>; 

# Using readline rather than <> 
# - Alright, but overly verbose 
while(defined (my $line = readline($stuff)) { 
    print "Line $. is : $line\n";  
} 

# Using IO::Handle methods on a lexical filehandle 
# - Alright, but overly verbose 
use IO::Handle; 
while(defined (my $line = $stuff->readline)) { 
    print "Line $. is : $line\n";  
}