Если ваша система Unix-подобный, и если вы AWK установлены, то у меня есть простого решения проблемы, которая дает вам доступ к тезаурусам в нескольких языков без подключения к Интернету и без окна сплита либо.
Первая загрузка LibreOffice тезаурусов из:
https://cgit.freedesktop.org/libreoffice/dictionaries/tree/
, например.
(Позаботьтесь е _ *. Даты файлов, это те, которые вам нужно, а не .aff и .DIC файлов, которые работают только для проверки орфографии с Hunspell.) Скачать * .dat тезаурусов понравившегося и скопировать их в подкаталог папки , где вы разместите свой плагин; этот подкаталог должен быть указан , «thes.».
Теперь создайте новый файл в папку плагинов (папку, в которой вы должны иметь «Thes» подкаталог с * .dat тезаурусов внутри) и поставить следующий в этом файле:
" offer choice among installed thesauri
" ==================================================
let s:thesaurusPath = expand("<sfile>:p:h") . "/thes"
function! s:PickThesaurus()
" 1, 1: glob does not ignore any pattern, returns a list
let thesaurusList = glob(s:thesaurusPath . "/*", 1, 1)
if len(thesaurusList) == 0
echo "Nothing found in " . s:thesaurusPath
return
endif
let index = 0
let optionList = []
for name in thesaurusList
let index = index + 1
let shortName = fnamemodify(name, ":t:r")
let optionList += [index . ". " . shortName]
endfor
let choice = inputlist(["Select thesaurus:"] + optionList)
let indexFromZero = choice - 1
if (indexFromZero >= 0) && (indexFromZero < len(thesaurusList))
let b:thesaurus = thesaurusList[indexFromZero]
endif
endfunction
command! Thesaurus call s:PickThesaurus()
Это позволит вам выбрать тезаурус по вашему выбору, набрав :Thesaurus в командном режиме Vim.
(На самом деле, если вы планируете использовать только один тезауруса, то вам не нужны никакие этого, просто присвоить полное имя файла тезауруса в буфер локальной переменной, b:thesaurus).
Наконец, добавьте следующие строки в ваш файл плагина:
" run awk on external thesaurus to find synonyms
" ==================================================
function! OmniComplete(findstart, base)
if ! exists("b:thesaurus")
return
endif
if a:findstart
" first, must find word
let line = getline('.')
let wordStart = col('.') - 1
" check backward, accepting only non-white space
while wordStart > 0 && line[wordStart - 1] =~ '\S'
let wordStart -= 1
endwhile
return wordStart
else
" a word with single quotes would produce a shell error
if match(a:base, "'") >= 0
return
endif
let searchPattern = '/^' . tolower(a:base) . '\|/'
" search pattern is single-quoted
let thesaurusMatch = system('awk'
\ . " '" . searchPattern . ' {printf "%s", NR ":" $0}' . "'"
\ . " '" . b:thesaurus . "'"
\)
if thesaurusMatch == ''
return
endif
" line info was returned by awk
let matchingLine = substitute(thesaurusMatch, ':.*$', '', '')
" entry count was in the thesaurus itself, right of |
let entryCount = substitute(thesaurusMatch, '^.*|', '', '')
let firstEntry = matchingLine + 1
let lastEntry = matchingLine + entryCount
let rawOutput = system('awk'
\ . " '" . ' NR == ' . firstEntry . ', NR == ' . lastEntry
\ . ' {printf "%s", $0}' . "'"
\ . " '" . b:thesaurus . "'"
\)
" remove dash tags if any
let rawOutput = substitute(rawOutput, '^-|', '', '')
let rawOutput = substitute(rawOutput, '-|', '|', 'g')
" remove grammatical tags if any
let rawOutput = substitute(rawOutput, '(.\{-})', '', 'g')
" clean spaces left by tag removal
let rawOutput = substitute(rawOutput, '^ *|', '', '')
let rawOutput = substitute(rawOutput, '| *|', '|', 'g')
let listing = split(rawOutput, '|')
return listing
endif
endfunction
" configure completion
" ==================================================
set omnifunc=OmniComplete
set completeopt=menuone
Это позволит вам получить синонимы любого слова, которое вы печатаете в режиме вставки . Еще находясь в режиме вставки, нажмите Ctrl-X Ctrl-O (или любую комбинацию клавиш , которую вы отобразили на omnicompletion), и всплывающее меню отобразит с перечнем синонимов.
Это решение очень грубо по сравнению с мощным плагином Чонга (см. Выше), но оно легкое и работает достаточно хорошо для меня. Я использую его с тезаурусами на четырех разных языках.
Вау, это потрясающе. Очень круто, и очень впечатляет. –
@ThadBrown Дайте ему пойти ~ И обратная связь приветствуется. : D – Chong
Трудная вещь для меня (как с точки зрения латентности, так и общего плагина) - это отсутствие действительно хорошего файла тезауруса. Например, вы хотите автоматическое завершение для огромной базы данных, вы можете просто запросить имена столбцов/таблиц, выполнить другой запрос для хранимых процедур и т. Д., А также привести результаты в файл словаря. Это может быть базовый источник автозаполнения. Есть ли там файл тезауруса, который лицензируется таким образом, что его можно перераспределять и изменять? Я мог бы очистить веб-сайт для меня, но это никому не помогло бы, если бы его нельзя было перераспределить. Мысли? –