Powerpoint глобальная кнопка

Question

Я думаю, что это простой вопрос, для кого с некоторыми VBA навыки Одер PowerPoint-профи:

У меня есть представление, как викторины, и я хотел бы предложить три джокера, как и в WWTBAM. Итак, я создал три кнопки, и я сделал кнопку 50:50, что при щелчке анимация начинается так, что неправильные ответы скрыты. Поэтому теперь я просто хочу, чтобы, щелкнув джокер-кнопку на одном слайде, его нужно удалить/отключить/скрестить на ВСЕ другие следующие слайды.

Есть ли кто-нибудь, кто может показать мне простой фрагмент, который это сделает?

Это было бы здорово. Спасибо!

Answer 1

Это должно вас происходит в правильном направлении:

Option Explicit 

' The name of the shape(s) to search for 
' (name shapes in the Selection Pane : Alt+F10 for PowerPoint 2010 and later) 
Public Const ShapeName = "50/50" 

' Purpose: Macro to HIDE all shapes on all slides that match the specified name 
' Usage: Assign to any shape(s) on a slide via the Insert Tab/Action/Mouse Click/Run Macro 
' Author: Jamie Garroch of YOUpresent Ltd. (http://youpresent.co.uk/) 
Public Sub HideAll() 
    Dim oSld As Slide 
    Dim oShp As Shape 
    For Each oSld In ActivePresentation.Slides 
    For Each oShp In oSld.Shapes 
     If oShp.Name = ShapeName Then oShp.Visible = msoFalse 
    Next 
    Next 
End Sub 

' Purpose: Macro to SHOW all shapes on all slides that match the specified name 
' Usage: Assign to any shape(s) on a slide via the Insert Tab/Action/Mouse Click/Run Macro 
' Author: Jamie Garroch of YOUpresent Ltd. (http://youpresent.co.uk/) 
Public Sub ShowAll() 
    Dim oSld As Slide 
    Dim oShp As Shape 
    For Each oSld In ActivePresentation.Slides 
    For Each oShp In oSld.Shapes 
     If oShp.Name = ShapeName Then oShp.Visible = msoTrue 
    Next 
    Next 
End Sub