ColdFusion 8: преобразовать ответ OData в массив

Question

Я пытаюсь обновить существующее приложение CF8, чтобы потреблять и загружать массив с результатами недавно обновленного ответа API RESTful с использованием OData.

Вот код в вопросе ... После извлечения данных из API, который отвечает строка OData JSon, код взрывает на последнюю строку, что inits Петли

<!--- Returned data is in json format so must change to an array. ---> 
<cfset local.result = deserializeJSON(myResult)> 

<!--- Reference the array collection of categories ---> 
<cfset local.collection = local.result> 

<!--- Initialize the output object ---> 
<cfset local.output = arrayNew(1)> 

<!--- Loop over the collection ---> 
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex"> 
... 

Это работает нормально используя предыдущий ответ JSON:

[ 
    { 
    "id": 1, 
    "name": "Blah, blah", 
    } 
] 

Единственное изменение, вносимое является обновленный JSON ответ:

[ 
    { 
    "@odata.context": "string", 
    "value": [ 
     { 
     "id": 1, 
     "name": "Blah, blah" 
     } 
    ] 
    } 
] 

Я уверен, что у меня что-то не хватает, но я никогда не работал над CF, так что здесь новая территория.

Мысли?

Спасибо!

ОБНОВЛЕНИЕ: Извините, если не указать более подробно. Вот как приложение в настоящее время использует ответ:

<!--- Loop over the collection ---> 
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex"> 

    <!--- Create a reference to the array element ---> 
    <cfset local.objectInstance = local.collection[local.arrayIndex]> 

    <!--- Create a new object reference ---> 
    <cfset local.thisObject = structNew()> 

    <!--- Seed the object properties ---> 
    <cfset local.thisObject.categoryId = local.objectInstance.id> 
    <cfset local.thisObject.categoryName = local.objectInstance.name> 

    <!--- Place the new object in the collection array ---> 
    <cfset arrayAppend(local.output, duplicate(local.thisObject))> 

</cfloop> 

А вот ошибка я получаю:

Error Occurred While Processing Request 
Object of type class coldfusion.runtime.Struct cannot be used as an array 

The error occurred in <path to file> line 97 

«Линия 97» является начать цикл доступных в обновлении выше:

Я попытался использовать подход «newJSON», предложенный Мигелем (спасибо вам большое за это!), Но, к сожалению, я столкнулся с той же ошибкой.

Еще раз спасибо! -Rich

Answer 1

Update после пользователь отправил больше информации

Если вы все еще получаете сообщение об ошибке, то вы сделали что-то неправильно. Вы должны изменить способ ссылки на новый объект данных JSON. Я создал новый Gist, используя обновленный код, который вы предоставили, чтобы вы могли увидеть, как это работает. TryCF Gist 2

В принципе, код в вашем <cfloop> должен выглядеть следующим образом. Опять же, обратите внимание, что на самом деле есть два блока <cfloop>. Это связано с тем, что новый формат JSON генерирует массив, содержащий другой массив.

<!--- Loop over the collection ---> 
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex"> 

    <cfloop from="1" to="#arrayLen(local.collection[local.arrayIndex].value)#" index="local.arrayIndex2"> 

     <!--- Create a reference to the array element ---> 
     <cfset local.objectInstance = local.collection[local.arrayIndex].value> 

     <!--- Create a new object reference ---> 
     <cfset local.thisObject = structNew()> 

     <!--- Seed the object properties ---> 
     <cfset local.thisObject.categoryId = local.objectInstance[local.arrayIndex2].id> 
     <cfset local.thisObject.categoryName = local.objectInstance[local.arrayIndex2].name> 

     <!--- Place the new object in the collection array ---> 
     <cfset arrayAppend(local.output, duplicate(local.thisObject))> 

    </cfloop> 

</cfloop> 

Смотрите GIST для получения более подробной информации, но это присваивает local.output массив, как это было раньше. В вашем исходном коде local.objectInstance внутри цикла была структурой. В новом формате JSON local.objectInstance внутри цикла теперь содержит массив структур. Поэтому вам нужно ссылаться на нее как таковую.

Оригинальный ответ перед тем вопрос был обновлен

С обновленной JSON вам нужно обновить, как ваш код ссылается на данные (которые вы не включили в исходное сообщение). Сделав некоторые предположения, я могу показать вам, как ссылаться на данные, используя приведенные вами примеры.

Первый для вашего первоначального примера. Вот какой код, который будет ссылаться и выводить данные для вас. Обратите внимание, что я включил тег <cfdump>. Вы захотите использовать это в ситуациях, подобных этому, где вам нужно см. данные. Функция deserializeJSON() анализирует JSON для вас и создает массив структур ColdFusion.

<cfset oldJSON = '[ { "id": 1, "name": "Blah, blah" } ]'> 

<!--- Returned data is in json format so must change to an array. ---> 
<cfset local.result = deserializeJSON(oldJSON)> 

<!--- Reference the array collection of categories ---> 
<cfset local.collection = local.result> 

<!--- Initialize the output object ---> 
<cfset local.output = arrayNew(1)> 

<cfdump var="#local.result#" label="Old JSON"> 

<!--- Loop over the collection ---> 
<cfoutput> 
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex"> 
    <p>#local.arrayIndex# - #local.collection[local.arrayIndex].id# - #local.collection[local.arrayIndex].name#</p> 
</cfloop> 
</cfoutput> 

Этот код дает этот вывод:

Вот пример обновленного кода, необходимого для получения тех же значений из нового формата JSON. Обратите внимание, что я добавил еще cfloop для ссылки на данные, потому что теперь есть два массива.

<cfset newJSON = '[ { "@odata.context": "string", "value": [ { "id": 1, "name": "Blah, blah" } ] } ]'> 
<!--- Returned data is in json format so must change to an array. ---> 
<cfset local.result = deserializeJSON(newJSON)> 

<!--- Reference the array collection of categories ---> 
<cfset local.collection = local.result> 

<!--- Initialize the output object ---> 
<cfset local.output = arrayNew(1)> 

<cfdump var="#local.result#" label="New JSON"> 

<!--- Loop over the collection ---> 
<cfoutput> 
<cfloop from="1" to="#arrayLen(local.collection)#" index="local.arrayIndex"> 
    <cfloop from="1" to="#arrayLen(local.collection[local.arrayIndex].value)#" index="local.arrayIndex2"> 
     <p>#local.arrayIndex# - #local.arrayIndex2# - #local.collection[local.arrayIndex].value[local.arrayIndex2].id# - #local.collection[local.arrayIndex].value[local.arrayIndex2].name#</p> 
    </cfloop> 
</cfloop> 
</cfoutput> 

Этот код дает этот вывод:

Я создал суть со всеми этим кодом, который вы можете играть вокруг с - TryCF Gist 1