Haskell: Проверьте, соблюдены ли все условия. Если они вернутся в противном случае false

Question

Я писал Haskell сегодня днем, и у меня есть список условий, которые должны быть удовлетворены. Если все они истинны, я хочу вернуть true, если один из них false, а затем возвращает false.

У меня есть метод, который работает, но мне просто интересно, есть ли лучший способ реализовать его для удобочитаемости/эффективности.

Вот что у меня есть:

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate 
    | gender candidate == preferedGender seeker 
    && gender seeker == preferedGender candidate 
    && minAcceptableAge seeker <= age candidate 
    && maxAcceptableAge seeker >= age candidate 
    && minAcceptableAge candidate <= age seeker 
    && maxAcceptableAge candidate >= age seeker = True 
    | otherwise = False 

Пол определяется как:

data Gender = Male | Female (Eq) 

Так что я просто выравнивали & & 'S и |' s, чтобы сделать это выглядеть немного лучше, но Я чувствую, что должен быть лучший способ, но, похоже, не может найти ничего, что бы искало Google.

Спасибо, продвинутый!

Answer 1

Вы можете потерять охранников и использовать and, чтобы проверить условия:

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate = and [ 
    gender candidate   == preferedGender seeker 
    , gender seeker    == preferedGender candidate 
    , minAcceptableAge seeker <= age candidate 
    , maxAcceptableAge seeker >= age candidate 
    , minAcceptableAge candidate <= age seeker 
    , maxAcceptableAge candidate >= age seeker 
    ] 

Answer 2

Ну, во-первых, вы можете and сторожевые условия просто с ,.

Далее, я должен реорганизовать minAccAge <= age && maxAccAge >= age скороговоркой в ​​специальную функцию, скажем,

acceptsAge :: Person -> Age -> Bool 
judge `acceptsAge` age 
    = age >= minAcceptableAge judge && age <= maxAcceptableAge judge 

Осталось

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate 
    | gender candidate == preferedGender seeker 
    , gender seeker == preferedGender candidate 
    , seeker `acceptsAge` age candidate 
    , candidate `acceptsAge` age seeker   = True 

Я бы оставить его в этом то, что два preferedGender проверки не может значительно сократятся.

Answer 3

Что вы спрашиваете, это вопрос стиля, поэтому нет правильного или неправильного ответа. Однако, вот несколько предложений.

Во-первых, вы пишете эквивалент этой модели:

isTrue value | value == True = True 
      | otherwise  = False 

Что, конечно, может быть упрощена:

isTrue value = value 

Во-вторых, как вы проверяете несколько тестов, которые все необходимость в Верно, вы можете использовать функцию and и передать свои тесты в качестве элементов списка. Это приведет к возврату True, если все элементы True, в противном случае это будет короткое замыкание и возврат False.

Подставив эти две идеи вместе мы получаем:

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate 
    = and [gender candidate == preferedGender seeker, 
     gender seeker == preferedGender candidate, 
     minAcceptableAge seeker <= age candidate, 
     maxAcceptableAge seeker >= age candidate, 
     minAcceptableAge candidate <= age seeker, 
     maxAcceptableAge candidate >= age seeker] 

... который, вероятно, как я хотел бы написать.

Answer 4

Вы могли бы злоупотреблять, может быть монады синтаксического сахара как:

a |==| b = guard $ a == b 
a |>=| b = guard $ a >= b 
a |<=| b = guard $ a <= b 
a |/=| b = guard $ a /= b 

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate = Just() == do 
    gender candidate |==| preferedGender seeker 
    gender seeker |==| preferedGender candidate 
    minAcceptableAge seeker |<=| age candidate 
    maxAcceptableAge seeker |>=| age candidate 
    minAcceptableAge candidate |<=| age seeker 
    maxAcceptableAge candidate |>=| age seeker 

Answer 5

Я заметил, что ваш код содержит некоторое дублирование, потому что вы проверить Eveything в обоих направлениях. Я хотел бы определить вспомогательную функцию checkAcceptable, что только одно направление и чем называть эту функцию дважды:

checkAcceptable :: Person -> Person -> Bool 
checkAcceptable seeker candidate = 
    gender candidate == preferedGender seeker && 
    minAcceptableAge seeker <= age candidate && 
    maxAccetableAge seeker >= age candidate 

checkMatch :: Person -> Person -> Bool 
checkMatch seeker candidate = 
    checkAcceptable seeker candidate && 
    checkAcceptable candidate seeker 

Answer 6

Для минимизации кода, вы можете написать его как этот

inRange x (a,b) = a <= x && x <= b 

checkOneWay a b = gender b == preferredGender a 
       && age b `inRange` (minAcceptableAge a, maxAcceptableAge a) 

checkMatch candidate seeker = checkOneWay candidate seeker 
          && checkOneWay seeker candidate