Firemonkey: Почему TBitmap.LoadFromFile() не работает?

Question

Окружающая среда: Delphi XE5, Win7

У меня есть приложение VCL. Хотите использовать классы Firemonkey для небольшой обработки изображений. Задача - получить эскизы из файлов изображений.

bmp: TBitmap; 
... 
bmp := FMX.Graphics.TBitmap.Create(100, 100); 
bmp.LoadThumbnailFromFile(filename, 100, 100); 

Любая комбинация TBitmap и LoadFromFile, LoadFromStream, CreateFromFile терпит неудачу с исключением.

Я попытался загрузить bmp, png, tif, jpg ... всегда тот же результат.

В отладчике я вижу исключение нарушения прав доступа в FMX.Canvas.D2D.pas в строке:

TCanvasD2D.ImagingFactory.CreateDecoderFromStream(stream, GUID_NULL, WICDecodeMetadataCacheOnDemand, dec); 

Что я должен сделать, чтобы избежать исключений и получить рабочий код? Чтобы включить некоторые кодеки?

ОБНОВЛЕНИЕ: На всех ... Можно ли использовать классы Firemonkey в приложении VCL? Он ищет меня, я не могу. Я прав?

UPDATE2: Теперь я стараюсь идти со следующим подходом Writing a FireMonkey DLL for use with a VCL application.

Моего FireMonkey DLL полного код

library wnimage; 

uses 
    System.SysUtils, 
    System.Classes, 
    FMX.Graphics; 

{$R *.res} 


function GetThumbnail(filename: String; width, height: Integer): TStream; 
var 
    bmp, th: TBitmap; 
begin 
    bmp := TBitmap.CreateFromFile(filename); 
    th := bmp.CreateThumbnail(width, height); 
    Result := TMemoryStream.Create; 
    th.SaveToStream(Result); 
    th.Free; 
    bmp.Free; 
end; 

exports 
    GetThumbnail; 

begin 
end. 

И снова я получаю такое же нарушение прав доступа в библиотеке строки:

bmp := TBitmap.CreateFromFile(filename); 

Answer 1

Я не уверен, какие части firemonkey вы можете использовать в VCL, но tbitmap из VCL не будет совместим с tbitmap с firemonkey в любом случае. Не уверен, насколько полезно использовать его в VCL, но чтобы избежать ошибки, вам нужно объявить переменную bmp как fmx tbitmap.

вар ВМР: FMX.Graphics.TBitmap

Answer 2

Следующая будет работать и тестируется в xe5 с UPDATE2 и исправлениями 1 + 3. Вы должны использовать Tbitmapsurface для того, чтобы получить savetostream использовать формат, который будет распознается при загрузке в VCL Timage. Вы не можете просто скопировать fmx tbitmap в vcl tbitmap.

unit Unit1; 

interface 

uses 
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics, 
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, fmx.graphics, Vcl.ExtCtrls, fmx.surfaces; 

type 
    TForm1 = class(TForm) 
    Button1: TButton; 
    OpenDialog1: TOpenDialog; 
    Image1: TImage; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.Button1Click(Sender: TObject); 

var bmp:fmx.graphics.tbitmap; 
    astream:tmemorystream; 
    surface:tbitmapsurface; 

begin 
    if opendialog1.Execute then 
    begin 
    bmp := FMX.Graphics.TBitmap.Create(100, 100); 
    bmp.LoadThumbnailFromFile(opendialog1.filename, 100, 100); 

    astream:=tmemorystream.Create; 
    surface:=tbitmapsurface.Create; 
    surface.Assign(bmp); 
    try 
    tbitmapcodecmanager.SaveToStream(astream,surface,'bmp'); 
    astream.Seek(0,tseekorigin.soBeginning); 
    image1.Picture.bitmap.LoadFromStream(astream); 
    finally 
     astream.free; 
     bmp.free; 
     surface.free 
    end; 
    end; 
end; 

end.