Как получить массив удаленных стен из кода генерации лабиринта Mathematica

Question

Я пытаюсь вытащить массив всех удаленных стен из этого кода генерации лабиринта. Кажется, он не работает, когда я прошу его распечатать, он даст мне всю решетку лабиринта, а не конкретные стены, о которых я прошу.

MazeGen2[m_, n_] := 
    Block[{$RecursionLimit = Infinity, 
    unvisited = Tuples[Range /@ {m, n}], maze, mazearray = {}, 
    mazeA}, 
    (*unvisited=Delete[unvisited,{{1},{2},{Length[ 
    unvisited]-1},{Length[unvisited]}}];*) 
    (*Print[unvisited];*) 

    maze = {{{{#, # - {0, 1}}, {#, # - {1, 0}}}} & /@ 
     unvisited, {{{0, n - 1}, {0, 0}, {m - 1, 
     0}}}};(*This generates the grid*) 
    Print[maze]; 
    {unvisited = DeleteCases[unvisited, #]; 
     (*Print[unvisited];*) 
     Do[ 
     If[MemberQ[unvisited, neighbor], 
     maze = DeleteCases[ 
      maze, {#, neighbor - {1, 1}} | {neighbor, # - {1, 1}}, {5}] 
     (*mazeA=Flatten[AppendTo[mazearray, 
     maze]];*) 
     ; #0@neighbor], 
     {neighbor, 
     RandomSample@{# + {0, 1}, # - {0, 1}, # + {1, 0}, # - {1, 
      0}}} 
     ] 
     } &@RandomChoice@unvisited; 

    Flatten[maze] 
    ]; 

Answer 1

Я разыскал свой код на Rosetta Code сайте, а также - в благодарность за это! - вот как использовать графическую альтернативу для генерации лабиринта. Это любезно пользователя AlephAlpha:

MazeGraph[m_, n_] := 
Block[{$RecursionLimit = Infinity, grid = GridGraph[{m, n}], 
visited = {}}, 
Graph[Range[m n], 
Reap[{AppendTo[visited, #]; 
    Do[ 
     If[FreeQ[visited, neighbor], 
     Sow[# <-> neighbor]; #0@neighbor], 
     {neighbor, RandomSample@AdjacencyList[grid, #]}]} & @ 
    RandomChoice@VertexList@grid][[2, 1]], 
GraphLayout -> {"GridEmbedding", "Dimension" -> {m, n}}, 
EdgeStyle -> Directive[Opacity[1], AbsoluteThickness[12], Purple], 
VertexShapeFunction -> None, 
VertexLabels -> "Name", 
VertexLabelStyle -> White, 
Background -> LightGray, 
ImageSize -> 300]]; 

width = height = 8; 

maze = MazeGraph[width, height] 

Solutions теперь легко, что лабиринт представляет собой график:

path = FindShortestPath[maze, 1, Last[VertexList[maze]]]; 
solution = Show[ 
    maze, 
    HighlightGraph[ 
    maze, 
    PathGraph[path], 
    EdgeStyle -> Directive[AbsoluteThickness[5], White], 
    GraphHighlightStyle -> None] 
    ]; 

, а также легко, чтобы найти удаленные стены - здесь это GraphDifference между оригиналом GridGraph и лабиринтом:

hg = HighlightGraph[ 
    GridGraph[{width, height}, 
    EdgeStyle -> 
    Directive[Opacity[0.2], Blue, AbsoluteThickness[1]]], 
    EdgeList[GraphDifference[GridGraph[{width, height}], maze]], 
    Background -> LightGray, 
    ImageSize -> 300, 
    GraphHighlightStyle -> {"Thick"}]; 

Показаны все три:

Row[{Labeled[maze, "maze"], Spacer[12], Labeled[hg, "deleted walls"], 
    Labeled[solution, "solution"]}] 

Извинения для вопросов моделирования - это сложная часть с использованием графиков ... :)