Как центрировать текст окна редактирования в Delphi7?

Question

В настоящее время я работаю над приложением BlackJack в Delphi7, и я пытаюсь центрировать текст окна редактирования, чтобы позже показать значение карты. Я нашел эту документацию (http://delphidabbler.com/tips/85), и теперь я не могу ее правильно реализовать. Я поместил код из ссылки в «Unit2», и теперь я пытаюсь вызвать обе функции в своих блоках редактирования из «Unit1», чтобы выровнять их текст. Всякий раз, когда я пытаюсь вызвать одну из двух функций, он говорит мне, что прошедшие параметры не идентичны. Если вы, ребята, смогли бы мне помочь, это было бы очень признательно.

Вот decleration из группы1:

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls,Unit2; 

type 
    TForm1 = class(TForm) 
    Edit1: TEdit; 
    Button10: TButton; 
    Button4: TButton; 
    Edit2: TEdit; 
    Edit3: TEdit; 

[...] 

Здесь код unit2:

unit Unit2; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls; 

type 
    TMyEdit = Class(TEdit) 
    public 
    FAlignment: TAlignment; 
    procedure SetAlignment(Value: TAlignment); 
    procedure CreateParams(var Params: TCreateParams); override; 
    property Alignment: TAlignment read FAlignment write SetAlignment; 
    end; 

implementation 

procedure TMyEdit.CreateParams(var Params: TCreateParams); 
begin 
    inherited CreateParams(Params); 
    case Alignment of 
    taLeftJustify: 
     Params.Style := Params.Style or ES_LEFT and not ES_MULTILINE; 
    taRightJustify: 
     Params.Style := Params.Style or ES_RIGHT and not ES_MULTILINE; 
    taCenter: 
     Params.Style := Params.Style or ES_CENTER and not ES_MULTILINE; 
    end; 
end; 

procedure TMyEdit.SetAlignment(Value: TAlignment); 
begin 
    if FAlignment <> Value then 
    begin 
    FAlignment := Value; 
    RecreateWnd; 
    end; 
end; 
end. 

Answer 1

Вы на самом деле не используя TMyEdit класс вообще. Вот почему Unit1 не может использовать функциональные возможности Unit2. Unit1 по-прежнему использует стандарт TEdit.

У вас есть два варианта:

1. Перемещение Unit2 в отдельный пакет, который регистрирует TMyEdit, а затем установить этот пакет в IDE. TMyEdit будет доступен во время разработки, и вы можете заменить элементы управления TEdit на элементы управления TMyEdit.

2. Если вы не хотите идти по этому пути, то альтернативой является переобъявить TMyEdit в TEdit и оставить Unit1 как есть. Он будет использовать последний тип TEdit, объявленный в предложении uses. Это известно как «Interposer класс», например:

   unit Unit2; 
   
   interface 
   
   uses 
       Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
       Dialogs, StdCtrls; 
   
   type 
       TEdit = Class(StdCtrls.TEdit) 
       public 
       FAlignment: TAlignment; 
       procedure SetAlignment(Value: TAlignment); 
       procedure CreateParams(var Params: TCreateParams); override; 
       property Alignment: TAlignment read FAlignment write SetAlignment; 
       end; 
   
   implementation 
   
   procedure TEdit.CreateParams(var Params: TCreateParams); 
   begin 
       inherited CreateParams(Params); 
       case Alignment of 
       taLeftJustify: 
        Params.Style := Params.Style or ES_LEFT and not ES_MULTILINE; 
       taRightJustify: 
        Params.Style := Params.Style or ES_RIGHT and not ES_MULTILINE; 
       taCenter: 
        Params.Style := Params.Style or ES_CENTER and not ES_MULTILINE; 
       end; 
   end; 
   
   procedure TEdit.SetAlignment(Value: TAlignment); 
   begin 
       if FAlignment <> Value then 
       begin 
       FAlignment := Value; 
       RecreateWnd; 
       end; 
   end; 
   
   end.