Преобразование двоичного кода в целое число для GetHashCode в Delphi

Question

Delphi 2009 добавила функцию GetHashCode в TObject. GetHashCode возвращает целое число, которое используется для хэширования в TDictionary.

Если вы хотите, чтобы объект работал хорошо в TDictionary, вам необходимо соответствующим образом переопределить GetHashCode таким образом, чтобы в целом разные объекты возвращали разные целые хэш-коды.

Но что вы делаете для объектов, содержащих двойные поля? Как вы превращаете эти двойные значения в целые числа для GetHashCode?

Как обычно это делается на Java, скажем, использовать метод Double.doubleToLongBits или Float.floatToIntBits. Последняя имеет документацию, которая описывает ее следующим образом: «Возвращает представление указанного значения с плавающей запятой в соответствии с форматом бит« одиночный формат »с плавающей точкой IEEE 754». Это связано с некоторыми побитовыми операциями с разными масками для разных бит значения с плавающей запятой.

Есть ли функция, которая делает это в Delphi?

Answer 1

Я хотел бы предложить следующее усовершенствование по сравнению с кодом Gamecat:

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1, FInt2 : Integer;) 
     1: (FDouble : Double;) 
    end; 

function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt1 xor arec.FInt2; 
end; 

Это учитывает все биты Дабл значение.

(комментарии не работают хорошо с кодом)

Answer 2

Если вы хотите отобразить двойной в целое число, вы можете использовать вариант запись:

type 
    TVarRec = record 
    case Integer of 
     0: (FInt : Integer;) 
     1: (FDouble : Double;) 
    end; 


function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt; 
end; 

Берегись, что это делает побитовую копию без интерпретации значений.

Другой (вид подвоха, использует абсолютные переменные:

function Convert(const ADouble: Double): Integer; 
var 
    tempDouble : Double; 
    tempInt : Integer absolute tempDouble; // tempInt is at the same memory position as tempDouble. 
begin 
    tempDouble := ADouble; 
    Result := tempInt; 
end; 

Answer 3

Нет необходимости делать что-то подобное, потому что значение по умолчанию GetHashCode уже возвращает число, которое гарантировано будет уникальным для каждого объекта: адрес памяти объекта. Кроме того, значение хэша по умолчанию не изменится, если вы измените данные, которые содержит ваш объект.

Предположим, у вас есть объект, содержащий Double со значением 3.5, и вы его используете и помещаете в словарь, и получаете хеш-код 12345678. У вас также есть что-то еще, содержащее ссылку на него , и это двойное поле изменяется, и теперь оно имеет значение 5,21. В следующий раз, когда вы попытаетесь вычислить его значение хеша, ваш хеш-код теперь будет 23456789, и ваш поиск не удастся.

Если вы не можете гарантировать, что это никогда не произойдет, и у вас есть действительно веская причина не использовать адрес памяти, лучше всего оставить GetHashCode таким, какой он есть. (Если он не сломался, не исправить.)

Answer 4

Я думаю, Java, что может быть реализовано в Delphi, как это:

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1: Integer;) 
     1: (FSingle: Single;) 
    end; 

function GetHashCode(Value: Double): Integer; 
var 
    arec: TVarRec; 
begin 
    arec.FSingle := Value; 
    Result := arec.FInt1; 
end; 

Идея заключается в снижении точности Double значение, соответствующее бинарному размеру целого (Sizeof (Single) = Sizeof (Integer)). Если ваши значения могут быть представлены в Одиночной точности без столкновения, это даст хорошее хэш-значение.

Редактировать: Поскольку типный тип не будет компилироваться в моем D2009, я адаптировал решение для записи вариантов.

Answer 5

Используйте CRC32 по двойным данным, потому что xor is evil.

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

type 
    TVarRec = record 
    case Integer of 
     0: (FInt1, FInt2 : Integer;); 
     1: (FDouble : Double;); 
    end; 

function Convert(const ADouble: Double): Integer; 
var 
    arec : TVarRec; 
begin 
    arec.FDouble := ADouble; 
    Result := arec.FInt1 xor arec.FInt2; 
end; 

var 
    FDoubleVar1, FDoubleVar2: TVarRec; 
    HashCode1, HashCode2: Integer; 
begin 
    // Make a Double 
    FDoubleVar1.FInt1 := $DEADC0DE; 
    FDoubleVar1.FInt2 := $0C0DEF00; 

    // Make another Double 
    FDoubleVar2.FInt1 := $0C0DEF00; 
    FDoubleVar2.FInt2 := $DEADC0DE; 

    WriteLn('1rst Double : ', FDoubleVar1.FDouble); 
    WriteLn('2nd Double : ', FDoubleVar2.FDouble); 

    HashCode1 := Convert(FDoubleVar1.FDouble); 
    HashCode2 := Convert(FDoubleVar2.FDouble); 

    WriteLn('1rst HashCode : ', HashCode1); 
    WriteLn('2nd HashCode : ', HashCode2); 

    if HashCode1 = HashCode2 then 
    begin 
    WriteLn('Warning: Same HashCode!'); 
    end; 
    ReadLn; 
end.