Нет данных после операции вставки VB.NET - Windows Forms and Web Service

Question

Веб-сервис VB.NET и ASMX. У меня по-прежнему возникают проблемы с получением данных после операции вставки.

Вот мой код вставки:

Try 
    'create a MySqlCommand to represent the query 
    If sqlConn.State = ConnectionState.Closed Then 
     sqlConn = New MySqlConnection(conStr) 
     sqlConn.Open() 
    End If 

    Dim myCommand As MySqlCommand = New MySqlCommand(strQuery, sqlConn) 
    If myCommand.ExecuteNonQuery() <> 0 Then 
     Result = True 
    End If 
Catch ex As Exception 
    Throw New ApplicationException("Error-luckie's server 2 " & ex.Message) 
Finally 
    sqlConn.Close() 
    sqlConn.Dispose() 
End Try 

strQuery будет простое утверждение вставки.

код для извлечения данных в виде набора данных следующим образом

Public Function ExecuteQuery(ByVal strQuery As String) As DataSet 
    Dim ds As DataSet = New DataSet 'create a DataSet to hold the results 

    Try 
     'create a MySqlCommand to represent the query 
     If sqlConn.State = ConnectionState.Closed Then 
      sqlConn = New MySqlConnection(conStr) 
      sqlConn.Open() 
     End If 

     Dim sqlcmd As MySqlCommand = sqlConn.CreateCommand() 
     sqlcmd.CommandType = CommandType.Text 
     sqlcmd.CommandText = strQuery 

     'create a MySqlDataAdapter object 
     Dim sqlDa As MySqlDataAdapter = New MySqlDataAdapter 
     sqlDa.SelectCommand = sqlcmd 

     Try 
      'fill the DataSet using the DataAdapter 
      sqlDa.Fill(ds, "Results") 
     Catch ex As Exception 
      Throw New ApplicationException("Error-luckie's server 1 " & ex.Message) 
     End Try 

    Catch ex As Exception 
     Throw New ApplicationException("Error-luckie's server 2 " & ex.Message) 
    Finally 
     sqlConn.Close() 
     sqlConn.Dispose() 
    End Try 

    Return ds 
End Function 

Я Вставка данных из одного потока и извлечением данных из других (не используется тот же экземпляр связи).

Это прекрасно работает, если я получаю данные через 15 минут.

Но я хочу получить результат сразу. Пожалуйста, помогите.

Answer 1

Я хотел бы изменить метод, как показано ниже

Public Function ExecuteQuery(strQuery As String) As DataSet 
    Dim ds As New DataSet() 

    Try 
     Using con = New MySqlConnection(conStr) 'using statements... 
      Using cmd = New MySqlCommand(strQuery, con) 'using statements... 
       Using sqlDa = New MySqlDataAdapter(cmd) 'using statements... 
        sqlDa.Fill(ds, "Results") 
       End Using 
      End Using 
     End Using 
    Catch ex As Exception 
     Throw New ApplicationException("Error-luckie's server 1 " + ex.Message) 
    End Try 

    Return ds 
End Function 

Public Function ExecuteNonQuery(strQuery As String) As Boolean 
    Try 
     Using con = New MySqlConnection(conStr) 'using statements... 
      Using cmd = New MySqlCommand(strQuery, con) 'using statements... 
       con.Open() 
       If cmd.ExecuteNonQuery() > 0 Then ' I have change the condition 
        Return True 
       End If 
      End Using 

     End Using 
    Catch ex As Exception 
     Throw New ApplicationException("Error-luckie's server 2 " + ex.Message) 
    End Try 
    Return False 
End Function