Преобразование многоразветвленного XML-документа в несколько XML-документов

Question

Нам нужно сделать несколько XML-документов, каждый из которых содержит один элемент информации из единого документа XML с неизвестным количеством элементов информации. Например, этот документ:

<alert> 
    <identifier>2.49.0.1.124.76fea972.2015</identifier> 
    <info> 
    <language>en</language> 
    </info> 
    <info> 
    <language>fr</language> 
    </info> 
</alert> 

должны давать эти два документа:

<alert> 
    <identifier>2.49.0.1.124.76fea972.2015</identifier> 
    <info> 
    <language>en</language> 
    </info> 
</alert> 

<alert> 
    <identifier>2.49.0.1.124.76fea972.2015</identifier> 
    <info> 
    <language>fr</language> 
    </info> 
</alert> 

Хотя обрезке братьев и сестер элемента «информация», нам нужно скопировать все узлы, атрибуты, пространства имен и т.д. всего предков (от корня), а также всех узлов, атрибутов, пространств имен и т. д. конкретного элемента информации.

Я новичок в XSLT и не понимаю, как это сделать. Любая помощь будет принята с благодарностью!

Answer 1

Используя процессор XSLT 2.0, как Saxon 9 или AltovaXML или XmlPrime вы можете использовать подход, как это:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

<xsl:template match="@* | node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* , node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:apply-templates select="alert/info" mode="split"/> 
</xsl:template> 

<xsl:template match="info" mode="split"> 
    <xsl:result-document href="language-{language}.xml"> 
    <xsl:apply-templates select="/*"> 
     <xsl:with-param name="info" select="current()" tunnel="yes"/> 
    </xsl:apply-templates> 
    </xsl:result-document> 
</xsl:template> 

<xsl:template match="info"> 
    <xsl:param name="info" tunnel="yes"/> 
    <xsl:if test=". is $info"> 
    <xsl:next-match/> 
    </xsl:if> 
</xsl:template> 

</xsl:stylesheet> 

Если вход в определенном пространстве имен, а затем использовать, например, <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xpath-default-namespace="urn:oasis:names:tc:emergency:cap:1.2">.

Если вы хотите запустить XSLT независимо от пространства имен, а затем использовать

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

<xsl:template match="@* | node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* , node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:apply-templates select="*:alert/*:info" mode="split"/> 
</xsl:template> 

<xsl:template match="*:info" mode="split"> 
    <xsl:result-document href="language-{language}.xml"> 
    <xsl:apply-templates select="/*"> 
     <xsl:with-param name="info" select="current()" tunnel="yes"/> 
    </xsl:apply-templates> 
    </xsl:result-document> 
</xsl:template> 

<xsl:template match="*:info"> 
    <xsl:param name="info" tunnel="yes"/> 
    <xsl:if test=". is $info"> 
    <xsl:next-match/> 
    </xsl:if> 
</xsl:template> 

</xsl:stylesheet> 

Answer 2

Легко в xsh:

my $orig := open file.xml ; 
for my $info in /alert/info { 
    my $clone := clone $orig ; 
    my $i = count($info/preceding::info) ; 
    delete $clone/alert/info[count(preceding::info) = $i] ; 
    save :f concat('file', $i, '.xml') $clone ; 
} 

Answer 3

Или, возможно, это немного проще, чем решение Мартина:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

<xsl:template match="/"> 
<xsl:for-each select="alert/info"> 
    <xsl:result-document href="language-{language}.xml"> 
    <alert> 
     <xsl:copy-of select="../identifier"/> 
     <xsl:copy-of select="."/> 
    </alert> 
    </xsl:result-document> 
</xsl:for-each> 
</xsl:template> 

</xsl:stylesheet>