Добавление вторичного управляющего направления в родительский объект в майя

Question

Я наткнулся на «скрипку заклепки», когда искал решение для движения змеиных весов. Мне нужно создать жесткий объект (шкалы) в постоянной точке деформирующего. Сценарий работает отлично, но теперь в процессе td у меня есть некоторые другие аспекты, которые мне нужно решить. Мне нужно дополнительное ограничение, кроме вершинного нормального вектора, полученного из родительского многоугольника, чтобы диктовать, как движется ребенок. План состоит в том, чтобы попытаться изменить сценарий так, чтобы вторичное направление следовало за потоком кромки к переднему концу объекта. Я надеюсь, что смогу легко переносить это векторное направление из самого края, но у меня есть ощущение, что это может быть не так просто. У меня ограниченный опыт, связанный с такими отношениями, основанными на ограничениях, с использованием продуктов dot и кросс-продуктов в houdini, но в Maya для меня это немного сложнее. Я уверен, что мне нужно только одно направление. Любые предложения по устранению этого? Я приложил несколько изображений к объекту с низким политестом, чтобы дать вам лучшую идею. Первый показывает оставшуюся кривую в положении покоя, а два вторых изображения показывают, как вторичная кривая отклоняется от идеального положения вектора вдоль поверхности тела змей.

Вот ссылка на сценарий https://www.creativecrash.com/maya/script/rivet-button/description#tabs

Наряду со ссылкой на опорном кадре https://drive.google.com/file/d/0B1O6s3CJ1wwlN1lOS1E1ZXVuOVk/view?usp=sharing

А вот сценарий,

// Copyright (C) 2000-2001 Michael Bazhutkin - Copyright (C) 2000 studio Klassika 
// www.geocites.com/bazhutkin 
// bazhutkin@mail.ru 
// 
// Rivet (button) 1.0 
// Script File 
// MODIFY THIS AT YOUR OWN RISK 
// 
// Creation Date: April 13, 2001 
// 
// 
// Description: 
// Use "Rivet" to constrain locator to polygon or NURBS surfaces 
// Select two edges on polygon object 
// or select one point on NURBS surface and call rivet 
// Parent your rivets and buttons to this locator 

global proc string rivet () 
{ 

string $nameObject; 
string $namePOSI; 

string $parts[]; 
string $list[] = `filterExpand -sm 32`; 
int $size = size($list); 
if ($size > 0) 
{ 
    if ($size != 2) 
    { error("No two edges selected"); 
     return ""; 
    } 

    tokenize($list[0],".",$parts); 
    $nameObject = $parts[0]; 
    tokenize($list[0],"[]",$parts); 
    float $e1 = $parts[1]; 
    tokenize($list[1],"[]",$parts); 
    float $e2 = $parts[1]; 

    string $nameCFME1 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge1"`; 
     setAttr ".ihi" 1; 
     setAttr ".ei[0]" $e1; 
    string $nameCFME2 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge2"`; 
     setAttr ".ihi" 1; 
     setAttr ".ei[0]" $e2; 
    string $nameLoft = `createNode loft -n "rivetLoft1"`; 
     setAttr -s 2 ".ic"; 
     setAttr ".u" yes; 
     setAttr ".rsn" yes; 

    $namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`; 
     setAttr ".turnOnPercentage" 1; 
     setAttr ".parameterU" 0.5; 
     setAttr ".parameterV" 0.5; 

    connectAttr -f ($nameLoft + ".os") ($namePOSI + ".is"); 
    connectAttr ($nameCFME1 + ".oc") ($nameLoft + ".ic[0]"); 
    connectAttr ($nameCFME2 + ".oc") ($nameLoft + ".ic[1]"); 
    connectAttr ($nameObject + ".w") ($nameCFME1 + ".im"); 
    connectAttr ($nameObject + ".w") ($nameCFME2 + ".im"); 
} 
else 
{ $list = `filterExpand -sm 41`; 
    $size = size($list); 

    if ($size > 0) 
    { 
     if ($size != 1) 
     { error("No one point selected"); 
      return ""; 
     } 
     tokenize($list[0],".",$parts); 
     $nameObject = $parts[0]; 
     tokenize($list[0],"[]",$parts); 
     float $u = $parts[1]; 
     float $v = $parts[2]; 
     $namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`; 
       setAttr ".turnOnPercentage" 0; 
       setAttr ".parameterU" $u; 
       setAttr ".parameterV" $v; 
     connectAttr -f ($nameObject + ".ws") ($namePOSI + ".is"); 
    } 
    else 
    { error("No edges or point selected"); 
     return ""; 
    } 
} 

string $nameLocator = `createNode transform -n "rivet1"`; 
createNode locator -n ($nameLocator + "Shape") -p $nameLocator; 

string $nameAC = `createNode aimConstraint -p $nameLocator -n ($nameLocator + "_rivetAimConstraint1")`; 
    setAttr ".tg[0].tw" 1; 
    setAttr ".a" -type "double3" 0 1 0; 
    setAttr ".u" -type "double3" 0 0 1; 
    setAttr -k off ".v"; 
    setAttr -k off ".tx"; 
    setAttr -k off ".ty"; 
    setAttr -k off ".tz"; 
    setAttr -k off ".rx"; 
    setAttr -k off ".ry"; 
    setAttr -k off ".rz"; 
    setAttr -k off ".sx"; 
    setAttr -k off ".sy"; 
    setAttr -k off ".sz"; 

connectAttr ($namePOSI + ".position") ($nameLocator + ".translate"); 
connectAttr ($namePOSI + ".n") ($nameAC + ".tg[0].tt"); 
connectAttr ($namePOSI + ".tv") ($nameAC + ".wu"); 
connectAttr ($nameAC + ".crx") ($nameLocator + ".rx"); 
connectAttr ($nameAC + ".cry") ($nameLocator + ".ry"); 
connectAttr ($nameAC + ".crz") ($nameLocator + ".rz"); 

select -r $nameLocator; 
return ($nameLocator); 

} 

rivet; 

Answer 1

Вместо того, чтобы использовать сценарий заклепок используйте встроенные волосяные фолликулы. Они несут с собой всю нормальную и касательную информацию, таким образом, могут быть анимированы через УФ-значения, и они предоставляют узел для группировки ваших ограниченных объектов.

Вы можете добавить фолликулы с помощью команд меню, рисуя их на поверхность и с помощью кода:

createNode "follicle" 
// follicleShape1 // (u should capture and use this name, im being lazy below) 
connectAttr ($targetMeshShape+".outMesh") "follicleShape1.inputMesh"; 
connectAttr ($targetMeshShape+".worldMatrix") "follicleShape1.inputWorldMatrix"; 
connectAttr "follicleShape1.outTranslate" "follicle1.translate"; 
connectAttr "follicleShape1.outRotate" "follicle1.rotate"; 

//UV attributes control placement on surface 
setAttr "follicleShape1.parameterU" $goToU; 
setAttr "follicleShape1.parameterV" $goToV; 

Но по этому вопросу, похоже, сценарий заклепки также использует УФ-значения для точек позиционирования. Таким образом, с хорошо ориентированными значениями UV * на вашей базовой сетке должно легко перемещаться либо заклепки, либо фолликулы вдоль поверхности, просто оживляя их значения УФ-излучения.

* Это означает отсутствие перекрывающихся УФ-лучей, всех вершин в пределах диапазона [0.0,1.0] и с УФ-осями, указывающими и перпендикулярными направлению потока соответственно.