Как сделать ссылки TextEdit кликабельными

Question

Этот сценарий должен открыть серию веб-страниц в новом окне браузера, а затем открыть TextEdit с предопределенным текстом и ссылками.
Safari выполняет то, что предполагается.
Редактирование текста открывает и вставляет текст, который я хочу, но ссылки не доступны.
Я знаю, что могу просто щелкнуть правой кнопкой мыши и выбрать «Замены»> «Добавить ссылки»> сам, но я пытаюсь автоматизировать весь процесс.
Я ценю ваше время и усилия от моего имени! Спасибо!

OpenWebPages() 
OpenTextEditPage() 

to OpenTextEditPage() 
-- Create a variable for text 
set docText to "" 
tell application "TextEdit" 
    activate 
    make new document 
    -- Define the text to be pasted into TextEdit 
    set docText to docText & "Some text to show in TextEdit." & linefeed & "  
    My favorite site about coding is http://stackoverflow.com/ 
    My favorite site for paper modeling is http://www.ss42.com/toys.html 
    My favorite site for inventing is http://www.instructables.com/howto/bubble+machine/ 
    " & linefeed & "Click the links above to improve your mind!" as string 
    -- Past the above text and links into TextEdit 
    set the text of the front document to docText & "" as string 
    tell application "System Events" 
     tell process "TextEdit" 
      -- highlight all text 
      keystroke "a" using command down 

      -- Think of a clever way to right click and choose Substitutions> Add Links> 
      -- Or think of another clever way to turn all URLs into links please. 

     end tell 
    end tell 
end tell 
end OpenTextEditPage 

to OpenWebPages() 
-- Start new Safari window 
tell application "Safari" 
    --  activate Safari and open the StackOverflow AppleScript page 
    make new document with properties {URL:"http://stackoverflow.com/search?q=applescript"} 
    -- Yoda is watching you 
    open location "http://www.ss42.com/pt/Yoda/YodaGallery/yoda-gallery.html" 
    -- Indoor boomerang 
    open location "http://www.ss42.com/pt/paperang/paperang.html" 
    -- Are you a Human ? 
    open location "http://stackoverflow.com/nocaptcha?s=f5c92674-b080-4cea-9ff2-4fdf1d6d19de" 
end tell 
end OpenWebPages 

Answer 1

Согласно this question Я построил этот маленький обработчик. Он принимает путь к вашему rtf-файлу, например makeURLsHyper((path to desktop folder as string) & "TestDoc.rtf"), и отлично справился с моими небольшими испытаниями. Но на данный момент это не касается форматирования текста.

on makeURLsHyper(pathOfRtfFile) 
    -- converting the given path to a posix path (quoted for later use) 
    set myRtfPosixPath to quoted form of (POSIX path of pathOfRtfFile) 
    -- RTF Hyperlink start 
    set rtfLinkStart to "{\\\\field{\\\\*\\\\fldinst HYPERLINK \"" 
    -- RTF Hyperlink middle 
    set rtfMiddlePart to "\"}{\\\\fldrslt " 
    -- RTF Hyperlink end 
    set rtfLinkEnd to "}}" 
    -- use sed to convert http-strings to rtf hyperlinks 
    set newFileContent to (do shell script "sed -i bak -e 's#\\(http[^[:space:]]*\\)#" & rtfLinkStart & "\\1" & rtfMiddlePart & "\\1" & rtfLinkEnd & "#g' " & myRtfPosixPath) 
end makeURLsHyper 

Иметь хороший день, Michael/Hamburg