sas: перекодировать кучу переменных сразу

Question

Предположим, у меня есть 10 переменных, все с одним и тем же префиксом (они начинаются с com).

Предположим, что переменные являются бинарными, и есть некоторые отсутствующие данные, и я хотел бы установить все эти отсутствующие данные в 0. Я хотел бы создать новую переменную для каждой исходной переменной, чтобы исходные данные были неповрежденными.

Как бы я переписал все эти переменные сразу? Есть ли простой способ запустить цикл в SAS? Если бы это был Python или R, я мог бы написать цикл, чтобы сделать все это с помощью grep или чего-то подобного.

EDIT: Вот что я пытаюсь сделать. Я хочу использовать unindexed массив с переменными com для создания их копий с именем new_com (префикс каждой переменной new). Затем я просто хочу перекодировать, что, как я знаю, я могу сделать с помощью операторов ifthen. Первая часть, о клонировании переменных, - это то место, где я застрял.

Answer 1

Ниже редактируется в случае, если вы не знаете, сколько переменных у вас есть, но вы знаете префикс вы хотите:

data test; 
    input coma comet compton communism come comb community comerade complete comma; 
    datalines; 
    1 1 1 0 0 . 0 0 1 . 
    ; 
run; 

%let prefix=com; 

/* output the list of variables and only keep those with prefix */ 
proc contents data = test noprint out=names(keep=name varnum); run; 

proc sort data = names; 
    by varnum; 
run; 

/* create your new variable with a "new_" prefix */ 
data names1; set names; 
    if index(name,"&prefix."); 
    new_name = "new_"||strip(name); 
run; 

/* put lists into macro variables */ 
proc sql noprint; 
    select name 
    into: old_vars separated by " " 
    from names1; 

    select new_name 
    into: new_vars separated by " " 
    from names1; 

    select count(*) 
    into: nobs 
    from names1; 
quit; 

%put &old_vars.; 
%put &new_vars.; 
%put &nobs.; 

/* use array and macro variables to manipulate data */ 
data test1; set test; 
    array old(&nobs.) &old_vars.; 
    array new(&nobs.) &new_vars.; 
     do i=1 to &nobs.; 
      if old(i) = . then new(i) = 0; 
       else new(i) = old(i); 
     end; 
    drop i; 
run; 

Answer 2

Предполагая, что вы SAS/STAT лицензии, это проще всего сделать с помощью PROC STDIZE:

data have; 
    array com[10]; 
    call streaminit(7); 
    do _j = 1 to 10; 
    do _i = 1 to 10; 
     if rand('Uniform') < 0.2 the com[_i]=.; 
     else com[_i]=1; 
    end; 
    output; 
    end; 
run; 

proc stdize data=have out=have_zero missing=0 reponly sprefix=new_ oprefix=old_; 
    var com:; 
run; 

reponly говорит не делать каких-либо стандартизации (только приписывать ноль для отсутствующих), sprefix и oprefix указать, что префикс унифицированные и оригинальные переменные.