Есть ли способ загрузить несколько конфигураций сразу в тестовый файл в alm, используя vba/macro?

Question

У меня возникла ситуация, когда мне нужно добавить несколько конфигураций для тестирования случаев в HP-ALM (Application Lifecycle Management).

Добавление 100-ти конфигураций вручную - это обыденная задача.

Есть ли способ загрузить несколько конфигураций одновременно с помощью макроса/vba для тестового примера в ALM?

Например: У меня есть шаг теста, как показано ниже, где добавлено поле параметра, и я хочу выполнить этот тестовый пример с разными значениями полей в отдельных тестовых примерах. Если в таблице будет проверено 100 полей, мне придется вручную добавить 100 конфигураций для одного тестового примера в alm. Удивительно, есть ли какой-либо скрипт vba, который может экспортировать конфиги, помещенные в столбец excel, и сопоставить его с указанным идентификатором теста.

В этом случае я должен добавить конфиги в мой тестовый пример для всех полей (EmpId, EmpName, EmpDesignation и т.д.) в таблице должно быть проверено:

config1: Verify_EmpID_in_Table-XYZ
config2: Verify_EmpName_in_Table- XYZ
config3: Verify_EmpDesignation_in_Table-XYZ

Answer 1

Ниже приведен код для загрузки объемных конфигураций с использованием TestID

Sub Add_Configurations() 

Dim qcURL As String 
Dim qcID As String 
Dim qcPWD As String 
Dim qcDomain As String 
Dim qcProject As String 
Dim tdConnection As Object 

On Error GoTo ErrHandler: 


    Set cnf = ThisWorkbook.Sheets("config") 

    qcURL = cnf.Cells(1, 2) 
    qcID = cnf.Cells(2, 2) 
    qcPWD = cnf.Cells(3, 2) 
    qcDomain = cnf.Cells(4, 2) 
    qcProject = cnf.Cells(5, 2) 


    Set tdConnection = CreateObject("TDApiOle80.TDConnection") 
    tdConnection.InitConnectionEx qcURL 
    tdConnection.Login qcID, qcPWD 
    tdConnection.Connect qcDomain, qcProject 


    lastrow = cnf.Cells(Rows.Count, 5).End(xlUp).Row 

    For i = 2 To lastrow 
     Test_Id = cnf.Cells(i, 5) 
     Set myTest = tdConnection.TestFactory.Item(Test_Id) 
     Set aNewConfig = myTest.TestConfigFactory.AddItem(Null) 
     aNewConfig.Name = cnf.Cells(i, 6) 
     aNewConfig.Post 
     Set aNewConfig = Nothing 
    Next 

MsgBox "Configurations successfully exported to ALM" & Chr(10) & "Please refresh to view the configurations" 
Exit Sub 

ErrHandler: 
MsgBox "!!!!! Error in exporting configurations !!!!!" & Chr(10) & "possible error causes: " & Chr(10) & Chr(10) & "1. Duplicate configuration name" & Chr(10) & "2. Configuration name is blank for a test id" 
Exit Sub 

End Sub