XSL: FO Different элемента списка метки на уровне

Question

Я использую Apache FOP для создания PDF-файлов из моего веб-приложения, где пользователи могут редактировать RichText с помощью CKEditor.

Моя проблема заключается в том, что пользователи иногда используют разные уровни отступов (un-) упорядоченные списки, например:

• уровень Элемент списка 1
  • уровень Элемент списка 2

CKEditor отображает различные бюллетени на уровень (или отступ), но сгенерированные PDF-файлы этого не делают, потому что мой шаблон выглядит так:

<!-- Lists --> 
<xsl:template match="ul|ol" mode="content"> 
    <xsl:apply-templates select="li" mode="content"> 
     <xsl:with-param name="ordered"> 
      <xsl:value-of select="name()='ol'"/> 
     </xsl:with-param> 
    </xsl:apply-templates> 
</xsl:template> 

<xsl:template match="li" mode="content"> 
    <xsl:param name="ordered"/> 
    <xsl:variable name="label"> 
     <xsl:choose> 
      <xsl:when test="$ordered='true'"> 
       <xsl:value-of select="position()"/> 
       . 
      </xsl:when> 
      <xsl:otherwise> 
       &#8226; 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:variable> 
    <fo:list-block padding-bottom="0pt"> 
     <fo:list-item> 
      <fo:list-item-label> 
       <fo:block> 
        <xsl:value-of select="$label"/> 
       </fo:block> 
      </fo:list-item-label> 
      <fo:list-item-body start-indent="body-start()"> 
       <fo:block> 
        <xsl:apply-templates mode="content"/> 
       </fo:block> 
      </fo:list-item-body> 
     </fo:list-item> 
    </fo:list-block> 
</xsl:template> 

Как я могу установить переменную метки в зависимости от того, на каком уровне отступов я нахожусь?

Что-то вроде:

• первого уровня: & # 8226
• второго уровня: & # 9702
• третьего уровня: & # 8269

Спасибо заранее, ~ Fabi

EDIT: Таким образом, решение, предложенное компанией @ fafl выглядит следующим образом:

<!-- Lists --> 
    <xsl:template match="ul|ol" mode="content"> 
     <xsl:param name="depth" select="0"/> 
     <xsl:apply-templates select="li" mode="content"> 
      <xsl:with-param name="ordered"> 
       <xsl:value-of select="name()='ol'"/> 
      </xsl:with-param> 
      <xsl:with-param name="depth"> 
       <xsl:value-of select="$depth + 1"/> 
      </xsl:with-param> 
     </xsl:apply-templates> 
    </xsl:template> 

    <xsl:template match="li" mode="content"> 
     <xsl:param name="depth" select="0"/> 
     <xsl:param name="ordered"/> 
     <xsl:variable name="label"> 
      <xsl:choose> 
       <xsl:when test="$ordered='true'"> 
        <xsl:value-of select="position()"/> 
        . 
       </xsl:when> 
       <xsl:otherwise> 
        <xsl:choose> 
         <xsl:when test="$depth = 1"> 
          &#8226; <!--filled circle--> 
         </xsl:when> 
         <xsl:when test="$depth = 2"> 
          &#9702; <!--not-filled circle--> 
         </xsl:when> 
         <xsl:otherwise> 
          &#9632; <!--black square --> 
         </xsl:otherwise> 
        </xsl:choose> 
       </xsl:otherwise> 
      </xsl:choose> 
     </xsl:variable> 
     <fo:list-block padding-bottom="0pt"> 
      <fo:list-item> 
       <fo:list-item-label> 
        <fo:block> 
         <xsl:value-of select="$label"/> 
        </fo:block> 
       </fo:list-item-label> 
       <fo:list-item-body start-indent="body-start()"> 
        <fo:block> 
         <xsl:apply-templates mode="content"> 
          <xsl:with-param name="depth"> 
           <xsl:value-of select="$depth"/> 
          </xsl:with-param> 
         </xsl:apply-templates> 
        </fo:block> 
       </fo:list-item-body> 
      </fo:list-item> 
     </fo:list-block> 
    </xsl:template> 

Answer 1

Попробуйте добавить параметр «глубину» для обоих шаблонов со значением по умолчанию 1. На каждом рекурсивном вызове «уль | ола» увеличить его на 1. Затем вы можете запросить его внутри обоих шаблонов.