cmake add_custom_command не работает

Question

Я пытаюсь запустить gperf из файла cmake.

Я создал (был) минимально CMakeLists.txt.

Когда я запускаю его

$ cmake . 
$ make 

Это не создает файл example.hpp

Что может быть проблема с ниже CMakeLists.txt?

cmake_minimum_required(VERSION 2.6) 

function(gperf_generate_new source target) 

     add_custom_target(${target} echo "Creating ${target}") 

     add_custom_command(
       SOURCE ${source} 
       TARGET ${target} 
       COMMAND gperf -L c++ ${source} > ${target} 
       OUTPUTS ${target} 
       DEPENDS ${source} 
       ) 

endfunction() 

gperf_generate_new(command_options.new.gperf example.hpp) 

Answer 1

Файлы, произведенный источник-файлы генераторов (как gpref) редко нужны как автономные. Вместо этого эти исходные файлы обычно используются для создания исполняемых файлов или библиотек внутри проекта.

Таким образом, стандартная схема с использованием генераторов исходного файла в CMake выглядит следующим образом:

# Call add_custom_command() with appropriate arguments for generate output file 
# Note, that *gperf* will work in the build tree, 
# so for file in the source tree full path should be used. 
function(gperf_generate_new input output) 
    add_custom_command(
     OUTPUT ${output} 
     COMMAND gperf -L c++ ${input} > ${output} 
     DEPENDS ${input} 
     COMMENT "Generate ${output}" # Just for nice message during build 
    ) 
endfunction() 

# Generate *example.hpp* file ... 
gperf_generate_new(${CMAKE_CURRENT_SOURCE_DIR}/command_options.new.gperf example.hpp) 

# ... for use it in executable 
add_executable(my_program ${CMAKE_CURRENT_BINARY_DIR}/example.hpp <other sources>) 

Если вы хотите только проверить генерирует ли example.hpp, вместо add_executable() использования

add_custom_target(my_target 
    ALL # Force target to be built with default build target. 
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/example.hpp 
) 

Примечание , эта связь между add_custom_command и add_custom_target выражается с использованием того же имени файла в их OUTPUT и DEPENDS вариантах соответственно. При таком порядке ссылок эти команды несущественны (но обе команды должны вызываться из того же сценария CMakeLists.txt).