Как я могу объединить все эти теги XML в один более крупный тег с тем же именем с помощью XSLT?

Question

Я преобразуя этот XML:

<root> 
    <contrib contrib-type="author"> 
    <name> 
     <last-name>Kottke</last-name> 
     <first-name>Leo</first-name> 
    </name> 
    </contrib> 

    <contrib contrib-type="author"> 
    <name> 
     <last-name>McKee</last-name> 
     <first-name>Andy</first-name> 
    </name> 
    </contrib> 

    <contrib contrib-type="author"> 
    <name> 
     <last-name>Hedges</last-name> 
     <first-name>Michael</first-name> 
    </name> 
    </contrib> 
</root> 

... с этим XSL:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes" method="xml"/> 
    <xsl:strip-space elements="*"/> 

    <!-- identity rule --> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

     <!-- Authors --> 
     <xsl:template match="contrib[@contrib-type='author']"> 
      <Authors> 
       <xsl:if test="position() != last()"> 
       <xsl:value-of select = "concat(name/first-name, ' ', name/last-name, ', ')" /> 
       </xsl:if> 

       <xsl:if test="position() = last()"> 
       <xsl:value-of select = "concat('and ', name/first-name, ' ', name/last-name, '.')" /> 
       </xsl:if> 
      </Authors> 
     </xsl:template> 
</xsl:stylesheet> 

... и я получаю этот выход:

<root> 
    <Authors>Leo Kottke, </Authors> 
    <Authors>Andy McKee, </Authors> 
    <Authors>and Michael Hedges.</Authors> 
</root> 

---

---

Однако, я пытаюсь объединить все   Author   тегов в одну большую   Author   тега, так что результат будет выглядеть примерно:

<root> 
    <Authors>Leo Kottke, Andy McKee, and Michael Hedges.</Authors> 
</root> 

Do Мне нужно каким-то образом использовать цикл  ?

Answer 1

No xsl:for-each Необходимо. Просто добавьте шаблон для /* (или /root) и удалить Authors из вашего contrib матча:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes" method="xml"/> 
    <xsl:strip-space elements="*"/> 

    <!-- identity rule --> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/root"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*"/> 
      <Authors> 
       <xsl:apply-templates select="contrib[@contrib-type='author']"/> 
      </Authors> 
     </xsl:copy> 
    </xsl:template> 

    <!-- Authors --> 
    <xsl:template match="contrib[@contrib-type='author']"> 
     <xsl:if test="position() != last()"> 
      <xsl:value-of select = "concat(name/first-name, ' ', name/last-name, ', ')" /> 
     </xsl:if> 

     <xsl:if test="position() = last()"> 
      <xsl:value-of select = "concat('and ', name/first-name, ' ', name/last-name, '.')" /> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

что-то немного проще

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="/root"> 
     <xsl:variable name="authors"> 
      <xsl:for-each select="contrib/name"> 
       <xsl:text>, </xsl:text> 
       <xsl:value-of select="first-name"/> 
       <xsl:text> </xsl:text> 
       <xsl:value-of select="last-name"/> 
      </xsl:for-each> 
     </xsl:variable> 

     <root> 
      <authors><xsl:value-of select="substring($authors,3)"/></authors> 
     </root> 
    </xsl:template> 

</xsl:stylesheet>