Не удалось найти соответствующий конструктор: java.time.LocalDateTime (java.lang.String)

Question

У меня есть Grails 3.1.2 приложение

Один из моих классов предметной области является цель

import java.time.LocalDateTime 
import java.time.temporal.ChronoUnit 

class Goal { 
    String name 
    String description 
    LocalDateTime targetDate 
    Date dateCreated 
    Date lastUpdated 
    static constraints = { 
     name(nullable: false, blank: false) 
    } 
} 

Когда я позвонить проверить на моем экземпляре цели я получаю: ошибка

• поля в объекте «com.liftyourgame.model.Goal» на поле «targetDate»: отвергнуто значения [2016-01-28T15: 10: 39.000Z] ; коды [com.lastyourgame.model.Goal.targetDate.typeMismatch.error, com.liftyourgame.model.Goal.targetDate.typeMismatch, goal.targetDate.typeMismatch.error, goal.targetDate.typeMismatch, typeMismatch.com.liftyourgame.model. Goal.targetDate, typeMismatch.targetDate, typeMismatch.java.time.LocalDateTime, typeMismatch]; arguments [targetDate]; сообщение по умолчанию [Не удалось найти подходящий конструктор для: java.time.LocalDateTime (java.lang.String)]

Как я могу изменить валидацию, чтобы он не нуждался в этом конструкторе?

Answer 1

Как изменить валидацию, чтобы он не нуждался в этом конструкторе?

Вы не можете, но проверка на самом деле не является проблемой. Проблема с связыванием данных. Связующее по умолчанию еще не имеет встроенной поддержки для LocalDateTime.

Вы можете зарегистрировать свой собственный конвертер, как это:

Преобразователь:

// src/main/groovy/demo/MyDateTimeConverter.groovy 
package demo 

import grails.databinding.converters.ValueConverter 

import java.time.LocalDateTime 
import java.time.format.DateTimeFormatter 

class MyDateTimeConverter implements ValueConverter { 
    @Override 
    boolean canConvert(Object value) { 
     value instanceof String 
    } 

    @Override 
    Object convert(Object value) { 
     def fmt = DateTimeFormatter.ofPattern("yyyy-MM-dd'T'HH:mm:ss.SSS'Z'") 
     LocalDateTime.parse(value, fmt) 
    } 

    @Override 
    Class<?> getTargetType() { 
     LocalDateTime 
    } 
} 

Зарегистрируйте как боб:

// grails-app/conf/spring/resources.groovy 
beans = { 
    myConverter demo.MyDateTimeConverter 
}