Вход команды командных переменных

Question

Я пытаюсь создать программу, которая называет и помещает пароль для точки доступа. У меня будет выбор, чтобы назвать мою точку доступа и ввести пароль. Пожалуйста, помогите, если вы это поймете.

@echo off 
Title KEVINS HOTSPOT UPLINK 
mode 100, 25 

// ЗДЕСЬ МОЯ ПРОБЛЕМА НАЧАЛА

echo Name your hotspot 
set/p "ssid=>%name%" 
echo Put a password for your hotspot: 
set/p "key=>%key%" 
netsh wlan set hostednetwork mode=allow ssid=%name% key=%key% 
goto choice 

// оставшийся код НИЖЕ

:choice 
echo Hotspot Uplink 
set/p "do=>" 
if %do%==Start goto start 
if %do%==start goto start 
if %do%==Stop goto stop 
if %do%==stop goto stop 
if %do%==End goto end 
if %do%==end goto end 
goto choice 

:start 
cls 
netsh wlan start hostednetwork 
goto choice 

:stop 
cls 
netsh wlan stop hostednetwork 
goto choice 

:end 
cls 
netsh wlan stop hostednetwork 
echo Thank you for using Kevin's Hotspot Uplink! 
pause 

Answer 1

set /p "varName=prompt text to show to user" 

Таким образом, это должно быть что-то вроде

set /p "ssid=Name your hotspot: " 
set /p "key=Put a password for your hotspot: " 
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key% 

Конечно, вы должны проверить, что пользователь ввел что-то (ех.)

set "ssid=" 
set /p "ssid=Name your hotspot: " 
if not defined ssid goto :eof 

А также, если пользователь вводит пустую строку, ваши if команды не удастся. Включите проверку для пустого значения или укажите сравниваемые строки.

:choice 
    echo Hotspot Uplink 
    set "do=" 
    set /p "do=>" 
    if /i "%do%"=="start" goto start 
    if /i "%do%"=="stop" goto stop 
    if /i "%do%"=="end" goto end 
    goto :choice