Вызов функции с динамическим массивом аргументов

Question

Если у меня есть

<cfset arr_arguments = ["a","b","c"]> 
<cfunction name="someFunction"> 
<cfargument name="someArgumentOne"> 
<cfargument name="someArgumentTwo"> 
<cfargument name="someArgumentThree"> 

</cffunction> 

Есть ли способ вызвать someFunction с аргументами arr_arguments, похожий на someFunction("a","b","c")? Я, конечно, знаю, что могу использовать argumentCollection, чтобы передать (привязанную) структуру к функции, но я специально спрашиваю о передаче в (без ключа) массива. В JS это можно легко сделать с someFunction.apply(this,arr_arguments), но в coldfusion я просто не могу найти способ сделать это.

Answer 1

Несущие аргументы передаются в функцию как структуру с числовыми ключами, соответствующими положениям аргументов, определенных в аргументах функции.Поэтому вместо того, передавая именованные аргументы, вы можете преобразовать массив в структуры с помощью цифровых клавиш, а затем передать структуры в с argumentCollection:

<cfset arr_arguments = {"1"="a","2"="b","3"="c"}> 
<cfset someFunction(argumentCollection=arr_arguments)> 

Вы можете легко преобразовать массив в структуры с помощью цифровых клавиш, как это :

<cfset args = {}> 
<cfloop from="1" to="#arrayLen(arr_arguments)#" index="i"> 
    <cfset args[i] = arr_arguments[i]> 
</cfloop> 

Answer 2

Хорошо, если вы хотите вызвать функцию с суровым массивом аргументов, лучшим вариантом, который я могу предложить, является создание функции-обертки. Ниже пример кода

<cfscript> 
    function testMe(
     required string arg1, 
     required string arg2 
    ) { 
     writedump(arguments); 
    } 

    function invokeFunction(
     required inFunction, 
     required array functionArguments 
    ) { 
     var stcArguments = {}; 
     // Introspect to get the method parameters 
     var arrFunctionArguments = GetMetaData(arguments.inFunction).parameters; 
     // Now figure out what we are iterating to 
     var numArgumentsToParse = Min(ArrayLen(arguments.functionArguments),ArrayLen(arrFunctionArguments)); 
     // Populate the arguments structure 
     for (var i=1;i<=numArgumentsToParse;i++) { 
      stcArguments[arrFunctionArguments[i].name] = arguments.functionArguments[i]; 
     } 
     // And try to call it 
     return arguments.inFunction(
      argumentCollection = stcArguments 
     ); 
    } 

    invokeFunction(testMe,[1,2]);   // Works fine 
    invokeFunction(testMe,[1,2,3,4]);  // Just skips 3 and 4 
// invokeFunction(testMe,[1]);    // Errors due to not enough arguments 
// invokeFunction(fakeFunctionName,[1]); // Errors due to undefined function 
</cfscript> 

Это будет ошибка, конечно, если выполняется одно из следующих действий произойдет

• один или несколько аргументов не правильного типа
• функция фактически не существует
• Не все необходимые аргументы передаются в

Но вы можете справиться с этим снаружи. Это будет использовать интроспекцию, чтобы определить имена аргументов, заполнить структуру соответствующим образом и вызвать запрошенную функцию.

Answer 3

Вот UDF, которая будет делать это для вас:

<cfscript> 
function test_function(a,b,c){  
    writeOutput("arguments.a"&arguments.a&"<br>"); 
    writeOutput("arguments.b"&arguments.b&"<br>"); 
    writeOutput("arguments.c"&arguments.c&"<br>"); 

    return arguments.a & "::" & arguments.b & "::" & arguments.c; 
} 

function invoke_positional(func,arr){ 
    var metaData = GetMetaData(func); 
    var args={}; 
    for(var pos=1;pos<=ArrayLen(arr);pos++){ 
     args[metaData.parameters[pos].name]=arr[pos]; 
    } 
    return arguments.func(argumentCollection=args); 
} 

data = ["StringOne","StringTwo",22]; 

result = invoke_positional(test_function,data); 

</cfscript> 

<cfoutput> 
<p> 
Returned: #result# 
</p> 
</cfoutput> 

invoke_positional работы, используя метаданные ОДС, чтобы создать именованный набор параметров, а затем использует их argumentCollection =

Answer 4

Так, один Опция, которую я обнаружил, заключается в том, чтобы создать объект аргументов отдельно от реальной области реальных аргументов и просто добавить значения к нему с помощью числового индекса.

<cfset args_input = createObject("java","com.naryx.tagfusion.cfm.engine.cfArgStructData").init()> 
<cfloop from="1" to="#arraylen(arr_arguments)#" index="i"> 
    <cfset args_input[i] = arr_arguments[i]> 
</cfloop> 
<cfset someFunction(argumentCollection=args_input)> 

Если вы столкнулись с такой ситуацией, используя Adobe ColdFusion, я бы посоветовал вам попробовать

<cfset correctClass = arguments.getClass().getName()> 

Чтобы получить строку перейти к CreateObject. Или, если это не работает, только есть специальная функция, чтобы возвращать пустой объект аргументов

<cfset args_input = this.generateArgumentObject()> 

и

<cffunction name="generateArgumentObject"> 
    <cfreturn arguments> 
</cffunction> 

Ну да ладно, все, что я знаю наверняка, что он будет работать точно в OpenBD и на основании сообщения, которое я видел в прошлом в блоге Бена Наделя, я вполне уверен, что это должно работать и в Adobe ColdFusion.

Answer 5

в Coldfusion 10, вы можете использовать invoke function, чтобы сделать это. По-видимому, это недокументированный способ передать массив аргументов по порядку. Пример в cfscript:

invoke('', 'someFunction', ['a','b','c']); 

Первый аргумент invoke это имя компонента (или пустая строка для UDF). Второй - это имя функции, а третий - массив аргументов. Обратите внимание, что имена компонентов и функций должны передаваться как строки.

Я протестировал это как с именами аргументов, так и без них, и порядок аргументов был сохранен.