Gnuplot генерации ключей Probleme

Question

У меня есть формат файла, как это:

2014/3/12 18:02:36 1 SSID1 
2014/3/12 18:02:37 1 SSID1 
2014/3/12 18:02:38 2 SSID2 
2014/3/12 18:02:39 1 SSID1 
2014/3/12 18:02:39 3 SSID3 
2014/3/12 18:02:39 3 SSID3 
2014/3/12 18:02:39 2 SSID2 

я создаю скрипт GNUPLOT для построения графика с календарным схемы -> дата в X и часов в Y с точками для каждой связи в качестве идентификатора SSID). Я использую переменную lc для генерации другого цвета из столбца (3).

Но я не могу иметь правильную легенду (ключ). С моим кодом у меня просто есть поле с первым SSID в столбце (4) с правильным цветом ... но как я могу иметь все SSID в этом поле со всем переменным цветом?

Если кто-то может помочь, спасибо!

Имейте славный день!

Answer 1

С title columnheader(4) вы выбираете четвертый столбец первой строки как ключевое слово для всего участка. Чтобы получить правильный заголовок, а также правильные цвета линии в ключе (см, например, Different color per dataset относительно основных цветов с linecolor variable) все возможное, чтобы создать список, содержащий все уникальные идентификаторы SSID, а затем перебрать их:

file = 'data2.dat' 
SSIDs = system(sprintf('awk ''{print $4}'' %s | sort | uniq', file)) 

set xdata time 
set ydata time 

set timefmt x "%Y/%m/%d" 
set timefmt y "%H:%M:%S" 

day = 360*24 
set xtics 70*day 

set format y "%H" 
set format x "%B %d" 

set style data points 

plot for [s=1:words(SSIDs)] file using (strcol(4) eq word(SSIDs, s) ? timecolumn(1) : 1/0):2:3 lc s pt 7 ps 1 t word(SSIDs, s) 

Примечание, что используя этот 1/0 трюк работает отлично при печати with points. Если по какой-то причине вы хотите построить линии, вы должны выполнить фильтрацию, используя, например, grep:

cmd(s, f) = sprintf('< grep ''%s'' %s', s, f) 
plot for [s=1:words(SSIDs)] cmd(s, file) using 1:2:3 lc s pt 7 ps 1 t word(SSIDs, s)