Обнаружение входящего символа XML «CR», затем преобразование в <br/>

Question

Я использую XSLT внутри ASP, он обслуживается msxml6.

Входящий XML, загруженный в объект, имеет «возврат каретки», который, я думаю, может быть ASCII 10. Я хотел бы преобразовать их в <br/> в вывод.

Я пытаюсь обнаружить 
 во входящем XML, но, похоже, это не находит. Я пробовал Javascript (JScript внутри ASP), безрезультатно.

Это происходит из MS Excel spreadsheetML, интересно.

Идеи по:

• , как он закодирован в объекте XML внутри msxsm6
• как обнаружить, а затем заменить <br/>?

Спасибо всем, stackoverflow отлично!

Answer 1

От http://www.w3.org/TR/2008/REC-xml-20081126/#sec-line-ends

XML проанализирована структура часто хранится в компьютерных файлах, которые, для редактирования удобства, которые организованы в линию . Эти линии обычно разделяются некоторой комбинацией символов ПЕРЕВОЗКА ПЕРЕВОЗКИ (#xD) и LINE FEED (#xA).

Для упрощения задачи приложений, процессор XML должен вести себя так, как будто он нормализуется все разрывы строк во внешних проанализированных (включая сущность документа) на входе до синтаксических, переводя как два -character sequence #xD #xA и любой #xD, за которым не следует #xA на один символ #xA.

Итак, это нормально искать 
 (или 
). Но обратите внимание, что только белые текстовые узлы из ввода могут сохраняться или не сохраняться в зависимости от поставщика дерева XML (синтаксический анализатор XML MSXSL не сохраняет эти текстовые узлы). Конечно, не пустое пространство, но только текстовые узлы.

Затем этот text назвал шаблон заменить новые строки с пустыми br элементов в XSLT 1.0:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="text()" name="text"> 
     <xsl:param name="pString" select="."/> 
     <xsl:choose> 
      <xsl:when test="contains($pString,'&#xA;')"> 
       <xsl:call-template name="text"> 
        <xsl:with-param name="pString" 
        select="substring-before($pString,'&#xA;')"/> 
       </xsl:call-template> 
       <br/> 
       <xsl:call-template name="text"> 
        <xsl:with-param name="pString" 
        select="substring-after($pString,'&#xA;')"/> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="$pString"/> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

С этим входом:

<root> 
<text> 
whatever 
</text> 
<text>and more</text> 
</root> 

Выход:

<root> 
<text><br />whatever<br /></text> 
<text>and more</text> 
</root> 

Answer 2

replace(replace(replace(XMLString, vbCrLf, ""), vbCr, ""), vbLf, "") 

Answer 3

Вот шаблон, который я использую для этого:

<xsl:template name="nl2br"> 
     <xsl:param name="contents" /> 

     <xsl:choose> 
       <xsl:when test="contains($contents, '&#10;')"> 
         <xsl:value-of select="substring-before($contents, '&#10;')" disable-output-escaping="yes" /> 
         <br /> 
         <xsl:call-template name="nl2br"> 
           <xsl:with-param name="contents" select="substring-after($contents, '&#10;')" /> 
         </xsl:call-template> 
       </xsl:when> 
       <xsl:otherwise> 
         <xsl:value-of select="$contents" disable-output-escaping="yes" /> 
       </xsl:otherwise> 
     </xsl:choose> 
</xsl:template>