Необходимость помощи синтаксиса Groovy для генерации закрытия из строки

Question

Я пытаюсь создать замыкание из строки. Код внутри замыкания ссылается на функцию сборки DSL(). Ошибки, которые я получаю, подразумевают, что Groovy пытается выполнить закрытие, а не просто объявлять его. Каков правильный синтаксис для этого? Вот некоторые из конструкций, которые я уже пробовал.

sh = new GroovyShell() 
cl = sh.evaluate('{ build("my job") }' } 
=> Ambiguous expression could be either a parameterless closure expression or an isolated open code block; 

sh = new GroovyShell() 
cl = sh.evaluate('L: { build("my job") }' } 
=> No signature of method: Script1.build() is applicable ... 

cl = Eval.me('L: { build("my job") }' } 
=> No signature of method: Script1.build() is applicable ... 

cl = Eval.me('L: { com.flow.FlowDelegate.build("my job") }' } 
=> No such property: com for class: Script1 

Пример, который я пытаюсь следовать приходит от: Load closure code from string in Groovy

Answer 1

В дополнение к Michael Easter's answer, можно также передать сценария привязки через к GroovyShell

def build = { -> 
    "BUILD $it" 
} 

def shell = new GroovyShell(this.binding) 
def c = shell.evaluate("{ -> build('tim_yates') }") 

c() 

Answer 2

Что о возвращении закрытие из сценария?

Eval.me("return { build('my job') } ") 

Что вы намерены использовать, что L:? Возвращение карты? Если это так, вы можете использовать квадратные скобки:

groovy:000> a = Eval.me("[L: { build('test for') }]") 
===> {L=Script1$_run_closure1@958d49} 
groovy:000> a.L 
===> Script1$_run_closure1@958d49 

Answer 3

Рассмотрим приведенный ниже пример. Ключ должен явно указывать замыкание без параметров.

def build = { def jobName -> 
    println "executing ${jobName}" 
} 

// we initialize the shell to complete the example 
def sh = new GroovyShell() 
sh.setVariable("build", build) 

// note "->" to specify the closure 
def cl = sh.evaluate(' { -> build("my job") }') 

println cl.class 
cl.call() 

Answer 4

Если вы оцениваете строку из сценария конфигурации DSL, вам не нужно создавать объект GroovyShell.

Ваш скрипт будет запущен как подкласс Script, который предоставляет удобный метод для оценки строки с текущей привязкой.

public Object evaluate(String expression) 
      throws CompilationFailedException 

A helper method to allow the dynamic evaluation of groovy expressions using this scripts binding as the variable scope 

Так что в этом случае вам просто нужно позвонить evaluate('{ -> build("my job") }').