Оценочные оценки SAS GLIMMIX

Question

Я пытаюсь проанализировать набор данных, где каждый субъект имеет 12 повторных мер (ежеквартально более 3 лет). Я хочу, чтобы субъекты оценивали временную диаграмму, чтобы оценить, значительно ли меняются субъекты с течением времени.

Код, который я в настоящее время последовательно предлагает, показывает, что каждый субъект демонстрирует значительное увеличение с течением времени. Это кажется маловероятным, но я не уверен, как настроить мой синтаксис для запуска более точной модели. Кто-нибудь знает, как/почему эта модель найдет коэффициент наклона для времени, значимого для всех случаев?

Краткое описание исследования: Мы создаем отчет о тенденциях, который должен отмечать коды процедур (субъектов), которые показывают значительное увеличение количества раз, когда он был выставлен счет за анализируемый период времени (3 года, по квартал). Исходная переменная рассматривается как счетчик (ограниченный 0, но не обязательно целые числа).

%macro Zeroes(numzeroes); 
    %local i; 
    %do i = 1 %to %eval(&numzeroes-1); 
     0 
    %end; 
    1; 
%mend; 

%macro EstimateStatement(numsubjects=); 
    %local i; 

    proc glimmix data=procdata11; 
     class code; 
     model billing_count=period_count/dist=NB link=log 
     solution ddfm=betwithin; 
     random intercept period_count/sub=code type=AR(1); 
     random _residual_; 
     %do i = 1 %to &numsubjects; 
     estimate "Slope for Code &i" period_count 1 | period_count 1/subject %Zeroes(&i); 
     %end; 
     ods output estimates=sscoeff; 
    run; 
%mend; 

%EstimateStatement(numsubjects=&num_codes) 

Любая помощь при создании этой модели более точной и эффективной была бы принята с благодарностью!

Спасибо!

Answer 1

Возможно, положительный уклон является фактической особенностью данных? Что вы видите, если вы набираете billing_count против period_count для каждого кода?

Что касается программы, у меня есть два предложения.

(1) Использование типа = AR (1) в

random intercept period_count/sub=code type=AR(1); 

заставляет дисперсия перехватывает равной дисперсии склонах. Это ограничение может быть несовместимо с данными. AR (1) не является разумной ковариационной структурой для модели случайных коэффициентов. Попробуйте тип = UN или type = UN (1).

(2) Падение

random _residual_; 

Его включение делает модель overspecified; отрицательное биномиальное распределение уже имеет масштабный параметр.

Еще одна вещь, которую следует учитывать, состоит в том, что модель случайных коэффициентов создает оценки усадки, так что оценки для отдельных кодов сокращаются в сторону общего решения: оценки наклона, которые вы получаете из модели случайных коэффициентов, не будут равны оценкам вы получите от отдельных регрессий для каждого кода. Kreft et al. имеют красиво интуитивное представление этой темы (см. p14 здесь http://tinyurl.com/ns99ojh).