Сохраненная процедура, содержащая множественные, если только выставляемые выписки

Question

Первый плакат! : D

Я искал ответ на этот вопрос повсюду, и так же просто, как я думаю, это должно быть, я не могу найти прямой ответ нигде. Я пытаюсь создать хранимую процедуру, которая будет хранить несколько, потенциально сотни операторов select ... Только один из них на самом деле закончится ... после того, как задан параметр @Look (т. Е. Имя таблицы).

Однако, я получаю эту ошибку:

Only one expression can be specified in the select list when the subquery is not introduced with EXISTS.

Ошибка указывает на заявления Else If и Else. Как я могу ввести exists в эти утверждения? Я пробовал настроить их безрезультатно.

Вот мой скрипт из базы данных образца:

CREATE PROCEDURE [dbo].[sp_Look] 
    (@Look varchar(50)) 
AS 
    DECLARE @Lookup VARCHAR(500) 

    IF (@Look = 'Employee_Information') 
     SET @Lookup = (SELECT EmployeeId, EmployeeSSN, EmployeeStatus 
         FROM Employee_Information) 
    Else If (@Look = 'Employee_Demographic') 
     SET @Lookup = (SELECT LastName, FirstName, DateOfBirth 
         FROM Employee_Demographic) 
    Else 
     SET @Lookup = 'No Table' 

    SELECT @Lookup 

Answer 1

Если мы можем сделать предположение, что значение переменной @Look будет именем таблицы, то все, что вам действительно нужно сделать, это установить переменную, содержащую имена столбцов. Хранимая процедура может выглядеть следующим образом:

CREATE PROCEDURE [dbo].[sp_Look] 
(@Look varchar(50)) 

AS 

SET NOCOUNT ON; 

-- check for sql injection 
IF CHARINDEX(';', ISNULL(@Look,'')) != 0 
BEGIN 
RAISERROR('Invalid input parameter', 16, 1) 
RETURN -1 
END 

Declare @SQL nvarchar(MAX);  

IF (@Look = 'Employee_Information') 
    SET @SQL = N'EmployeeId, EmployeeSSN, EmployeeStatus'      
ELSE IF (@Look = 'Employee_Demographic') 
    SET @SQL = N'LastName, FirstName, DateOfBirth' 

IF (@SQL is not null) 
BEGIN 
    SET @SQL = N'SELECT ' + @SQL + ' FROM '+ QUOTENAME(@Look) + ';'; 
    EXEC sys.sp_executesql @SQL; 
END 
ELSE 
    SELECT 'No Table' 

Answer 2

не знаю, почему вы делаете это, но если вы должны по какой-то странной причине, сделать это что-то вроде этого .....

Create Procedure [dbo].[usp_Look] --<-- do not use sp_ prefix for user procs 
@Look SYSNAME      --<-- Use appropriate data type for sql server objects 
AS 
BEGIN 
    SET NOCOUNT ON; 
    Declare @Sql nvarchar(MAX); 

     -- Use dynamic sql rather than using if..else blocks 
IF OBJECT_ID(@Look) IS NOT NULL 
BEGIN 
    SET @Sql = N' SELECT * FROM ' + QUOTENAME(@Look) + ';'; 
    EXEC sys.sp_executesql @Sql; 
END 
ELSE 
    BEGIN 
    SELECT 'Table Does not exists'; 
    END 

END