См. Все аргументы, переданные в командной строке из определенного индекса в конец - пакетный скрипт

Question

Предположим, что передаю некоторые аргументы из командной строки в пакетный скрипт. Нравится: myfile.bat flower, tree, doge, cate, house Но длина списка аргументов динамическая, а не 5 все время. Как я могу получить все аргументы от n до последнего. Например, если n было 2, что я должен писать, чтобы получить дож, кат, дом. Редактировать на основе вопроса комментариев.

Answer 1

@ECHO OFF 
SETLOCAL 
SET /a skipargs=2 
SET "destvar=somevarname" 

CALL :getargs %* 

SET somevarname 

SET /a skipargs=1 
SET "destvar=somevarname" 

CALL :getargs %* 

SET somevarname 


GOTO :EOF 

:getargs 
IF %skipargs% gtr 0 SET /a skipargs-=1&shift&GOTO getargs 
SET "%destvar%=" 
:getargsl 
IF DEFINED %destvar% (CALL SET "%destvar%=%%%destvar%%% %1" 
) ELSE (
SET "%destvar%=%1" 
) 
SHIFT 
IF "%~1" neq "" GOTO getargsl 
GOTO :eof 

Это должно продемонстрировать, как назначить все арг после п-й к переменной.

Answer 2

попробовать

@echo off 

set/a skip=1 & rem set skip to the number of arguments to forget 
for /L %%i in (1,1,%skip%) do shift & rem skip arguments 

:getArg 
echo %~1 & shift 
if "%~1" neq "" goto :getArg 
exit/B  

Answer 3

Это кажется немного проще, (для меня по крайней мере).

@Echo Off 
Set "n=2" 
For /F "Tokens=%n%*" %%A In ("%*") Do Set "remainder=%%B" 
Echo(%remainder% 
Timeout -1 

Изменить значение переменной п на второй линии в соответствии с требованиями

Answer 4

Ниже приведен вариант с использованием for петлю на %* (это отображает все, но первые _NUMSKIP аргументы):

@echo off 
set /A "_NUMSKIP=2" 
set /A "INDEX=0" 
for %%A in (%*) do (
    set /A "INDEX+=1" 
    setlocal EnableDelayedExpansion 
    if !INDEX! GTR %_NUMSKIP% (
     endlocal 
     echo(%%A 
    ) else endlocal 
) 

Обратите внимание, что это небезопасно для всех строк; например, аргумент &"&" вызывает синтаксическую ошибку!

---

Чтобы собрать оставшиеся аргументы в одной строке для последующей передачи в исполняемый файл, это помогает:

@echo off 
set /A "_NUMSKIP=2" 
set /A "INDEX=0" & set "ARGS= " 
for %%A in (%*) do (
    set /A "INDEX+=1" 
    set "ARGV=%%A" 
    setlocal EnableDelayedExpansion 
    if !INDEX! GTR %_NUMSKIP% (
     for /F "delims=" %%B in (^""!ARGS!!ARGV!"^") do (
      endlocal 
      set "ARGS=%%~B " 
     ) 
    ) else endlocal 
) 
setlocal EnableDelayedExpansion 
echo(!ARGS:~1,-1! 
endlocal 

Обратите внимание, что первоначальные аргументы разделители становятся заменены одним ПРОСТРАНСТВОМ каждыми.