Gnuplot 3D - точки разброса точек и поверхность * и * линии между ними

Question

Я не смог найти способ создания сюжета, описанного в названии, знает ли кто-нибудь, как это сделать, если это возможно? Я хотел бы построить поверхность из функции и отобразить точки из файла, а также провести линии между точками и поверхностью. Ниже приведено изображение, которое содержит пример того, что я хотел бы сделать, взятый из вопроса stackoverflow для идентичной задачи (но для другой программы построения графиков).

Answer 1

Вы можете сделать расчеты внутри using заявления GNUPLOT в. Для линий я использую стиль vectors построения графиков, и с arrowstyle variable (или linecolor variable) вы можете выбрать различные цвета в зависимости от значения dz:

set style arrow 1 linecolor rgb 'red' nohead 
set style arrow 2 linecolor rgb 'green' nohead 

splot f(x,y) with lines, \ 
    'points.dat' using 1:2:(f($1,$2)):(0):(0):(dz=$3-f($1,$2)):(dz < 0 ? 1 : 2) with vectors arrowstyle variable,\ 
    '' using 1:2:3 with points pt 7 ps 5 

Я не уверен, что это создает проблемы с Gnuplot 4.6. В вашем случае вы можете также использовать linecolor variable или linecolor rgb variable, чтобы изменить цвет вертикальных линий:

splot f(x,y) with lines, \ 
    'points.dat' using 1:2:(f($1,$2)):(0):(0):(dz=$3-f($1,$2)):(dz < 0 ? 0xff0000 : 0x00ff00) with vectors nohead linecolor rgb variable lw 5,\ 
    '' using 1:2:3 with points pt 7 ps 5