Perl (tk): как запустить асинхронно системную команду, чтобы реагировать на ее вывод?

Question

Я пишу обертку к внешней команде («sox», если это может помочь) с Perl «Tk». Мне нужно запустить его асинхронно, конечно, чтобы не блокировать MainLoop() tk tk. Но мне нужно прочитать его вывод, чтобы уведомить пользователя о прогрессе команды.

Я проверяю решение, как этот, используя IPC :: open3:

{ 
    $| = 1; 
    $pid = open3(gensym, ">&STDERR", \*FH, $cmd) or error("Errore running command \"$cmd\""); 
} 
while (defined($ch = FH->getc)) { 
    notifyUser($ch) if ($ch =~ /$re/); 
} 
waitpid $pid, 0; 
$retval = $? >> 8; 
POSIX::close($_) for 3 .. 1024; # close all open handles (arbitrary upper bound) 

Но, конечно, блоки цикла в то время как MainLoop до $ ЦМД это прекратить.

Есть ли способ считывать выходные данные асинхронно? Или я должен идти со стандартным вилкой? Решение также должно работать под win32.

Answer 1

Для неблокирующего считывания дескриптора файла взгляните на Tk::fileevent.

Вот пример скрипта, как можно использовать трубу, раздвоенный процесс, и fileevent вместе:

use strict; 
use IO::Pipe; 
use Tk; 

my $pipe = IO::Pipe->new; 
if (!fork) { # Child XXX check for failed forks missing 
    $pipe->writer; 
    $pipe->autoflush(1); 
    for (1..10) { 
     print $pipe "something $_\n"; 
     select undef, undef, undef, 0.2; 
    } 
    exit; 
} 
$pipe->reader; 

my $mw = tkinit; 
my $text; 
$mw->Label(-textvariable => \$text)->pack; 
$mw->Button(-text => "Button", -command => sub { warn "Still working!" })->pack; 
$mw->fileevent($pipe, 'readable', sub { 
        if ($pipe->eof) { 
         warn "EOF reached, closing pipe..."; 
         $mw->fileevent($pipe, 'readable', ''); 
         return; 
        } 
        warn "pipe is readable...\n"; 
        chomp(my $line = <$pipe>); 
        $text = $line; 
       }); 
MainLoop; 

Разветвление может или не может работать под Windows. Также нужно быть осторожным при разрыве внутри Tk; вы должны убедиться, что только один из двух процессов делает вещи X11/GUI, иначе будут плохие вещи (ошибки X11, сбои ...). Хорошим подходом является разветвление перед созданием Tk MainWindow.