awk манипулирует csv-файлом

Question

Я хочу использовать awk для чтения csv-файла. Файл csv содержит 5 столбцов, c1, c2, c3, c4, c5. Я хочу судить, что c1, c2 и c3 вместе уникальны, как ограничение базы данных.

здесь пример CSV файл:

c1,c2,c3,c4,c5 
1886,5141,11-2011,62242.57,52.71 
1886,5140,11-2011,63763.75,52.22 
23157666,4747,11-2011,71.07,83.33 
1886,5141,11-2011,4645.45,2135.45 

В этом случае, row1 и row4 нарушают ограничение уникальности, и подсказать сообщение об ошибке.

Как реализовать его с помощью awk? Заранее большое спасибо.

Answer 1

В этом списке перечислены все линии для каждого дублирования. Он только выводит сообщение дублирования раз для каждого набора.

awk -F, '{count[$1,$2,$3]++; line[$1,$2,$3] = line[$1,$2,$3] ", " NR} END {for (i in count) {if (count[i] > 1) {v=i; gsub(SUBSEP, FS, v); print "Error: lines", substr(line[i], 3), "collide on value:", v}}}' 

Разразившийся на нескольких линиях:

awk -F, ' 
    { 
     count[$1,$2,$3]++; 
     line[$1,$2,$3] = line[$1,$2,$3] ", " NR 
    } 
    END { 
     for (i in count) { 
      if (count[i] > 1) { 
       v = i; 
       gsub(SUBSEP, FS, v); 
       print "Error: lines", substr(line[i], 3), "collide on value:", v 
      } 
     } 
    }' 

Это вариация на ответ Кевина.

Answer 2

awk -F, 'line[$1,$2,$3] {printf "Error: lines %d and %d collide\n", line[$1,$2,$3], NR; next} {line[$1,$2,$3] = NR}'