Создайте серию фибоначчи без петли или управления потоком в APL

Question

Есть ли способ создать последовательность фибоначчи в APL с помощью однострочной линии, которая не требует циклов или управления потоком?

Я сделал это с помощью функции → и условного теста, но я чувствую, что должен быть более элегантный, декларативный способ. example, что я нашел, что претензии на это на одной строке не работают на gnu-apl - кажется, что он на правильном пути, используя математическую математику, но мне тяжело идти дальше, t настроить его для правильной работы.

Я преследую APL как свой первый реальный язык программирования (мне нравятся символы. Я просто делаю.) Я сейчас использую Project Euler как способ лучше познакомиться.

Answer 1

Мне тоже нравятся символы APL, а также его мощность программирования в массиве. Другие языки массива могут быть более мощными, например J, но им не хватает красоты символов APL и явного синтаксиса.

Я просто попытался пример вы ссылку в GNU APL и работает все в порядке:

 ↑0 1↓↑+.×/5/⊂2 2⍴1 1 1 0 
5 
     ↑0 1↓↑+.×/6/⊂2 2⍴1 1 1 0 
8 
     ↑0 1↓↑+.×/7/⊂2 2⍴1 1 1 0 
13 

Если вы не можете заставить его работать, убедитесь, что:

• типа (или скопировать и вставить) точные символы, показанные в примере: в частности × - U + 00D7 MULTIPLICATION SIGN, а не X; ⍴ U + 2374 APL FUNCTIONAL SYMBOL RHO, а не любой другой греческий Rho, и определенно не P; ⊂ U + 2282 SUBSET OF; и так далее;
• проверять некоторые цифры, отличные от 1 или 5, потому что они являются единственными числами, которые равны их числу Фибоначчи;
• Если вы не ставите фактическое число вместо N, убедитесь, что вы правильно определили N, например N←7 в предыдущей строке.

Если вы все еще не можете заставить его работать, введите формулу один шаг в то время, начиная с правой стороны:

 2 2⍴1 1 1 0 
1 1 
1 0 
     ⊂2 2⍴1 1 1 0 
1 1 
1 0 
     7/⊂2 2⍴1 1 1 0 
1 1 1 1 1 1 1 1 1 1 1 1 1 1 
1 0 1 0 1 0 1 0 1 0 1 0 1 0 
     +.×/7/⊂2 2⍴1 1 1 0 
21 13 
13 8 
     ↑+.×/7/⊂2 2⍴1 1 1 0 
21 13 
13 8 
     0 1↓↑+.×/7/⊂2 2⍴1 1 1 0 
13 
8 
     ↑0 1↓↑+.×/7/⊂2 2⍴1 1 1 0 
13 

Что касается названия вопроса, я думаю, что эта матрица формула ногти он (! браво @mappo)

Если бы я был golfing, я бы, вероятно, использовать более короткий вариант, но это все:

 2⌷∊+.×/7/⊂∘.∨⍨1 0 
13 

Там, сюда м от 24 до 17 символов. Посмотрите, можете ли вы это выяснить :-)

GNU APL в порядке, хотя ему не хватает некоторых современных функций, но сохраните копию руководства Dyalog APL Programmer's Guide & Язык Ссылка удобна, поскольку это одна из самых полных ссылок на язык.

Answer 2

Другой способ сделать это будет использовать (относительно новый) оператор мощности. Это может или не может поддерживаться GNU APL, оно работает с Dyalog (я использую 13.1) и APN NGN.

Попробуйте

({⍵,+/¯2↑⍵} ⍣ 20) (1 1) 

Как и другие примеры, итерация скрыта, здесь с оператором питания.

Выражение

({⍵,+/¯2↑⍵} ⍣ 3) (1 1) 

делает

{⍵,+/¯2↑⍵} {⍵,+/¯2↑⍵} {⍵,+/¯2↑⍵} 1 1 

под одеялом.

1 1 - это начальное значение, и каждый последующий {⍵, +/¯2 ↑ ⍵} просто связывает сумму двух последних элементов.

Answer 3

Вы используете Dyalog APL? В этом случае вы должны воспользоваться оператором power, как объяснялось предыдущим ответом (первый фрагмент кода в этом ответе, исходящий из книги Освоение Dyalog APL, стр. 416).

Другое решение с тем же оператором будет с матрицами:

(+.×⍣10)⍨ 2 2⍴1 1 1 0 

или как прямой функции:

{⊃(+.×⍣⍵)⍨2 2⍴1 1 1 0} 10 

Если вы не хотите использовать оператор power, вы все равно (код ниже проверен в соответствии с GNU APL 1.5):

{+.×/⍵⍴⊂2 2⍴1 1 1 0} 10 

Answer 4

Хорошо, я думаю, я нашел способ, чтобы генерировать последовательность длины N (а не энного количества) в один (хотя и не очень красивая линия APL2):

+/¨(⊂0 0)⍉¨⊖¨(2/¨⍳N)↑¨⊂P←V∘.!V←⍳1+N←20 

Как я сказал: не так Симпатичная. Позвольте мне попытаться разбить его на идиомы:

Это треугольник Паскаля с 20 уровнями:

P←V∘.!V←⍳1+N←20 

Тогда мы возьмем N первый верхний левый-угловые квадраты:

(2/¨⍳N)↑¨⊂P 

Эта идиома возвращает главную диагональ матрицы:

(⊂0 0)⍉ 

Но мы хотим, а, nti-diagonal, поэтому перед этим мы будем использовать ⊖, чтобы перевернуть все квадраты.

Последний шаг состоит в том, чтобы суммировать все диафрагмы с +/.

Answer 5

Late к партии, но вот чистое решение, которое безопасно для Гну-APL, не используя оператор мощности, и немного тонкой настройки «нег-два взять» метод Лобачевского:

fib ← {{⍵, +/ ¯2↑ ⍵}/⌽ ⍳⍵} 

Основной трюк: изменяя список iota, так как сжатие читает его в обратном порядке.Выход образца:

 fib 10 
1 1 2 3 5 8 13 21 34 55