Получение файла в пакетном файле, где известно имя файла

Question

Я пытаюсь написать простой командный файл, который позволяет мне сравнивать два файла, в которых оба имени файла уже известны и заданы в самом пакетном файле.

Но просто получить один файл нелегко. Вот маленький кусок кода, который воспроизводит проблему:

IF EXIST "flava.jpg" (

    REM Get current filesize 
    FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA 

    ECHO %_existingFileSize% 

) ELSE (

    ECHO File not found. 

) 

Из того, что я прочитал here, он должен повторить содержимое переменной. Что происходит?

Answer 1

setlocal enabledelayedexpansion 
IF EXIST "flava.jpg" (
    REM Get current filesize 
    FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA 
    ECHO !_existingFileSize! 
) ELSE (
    ECHO File not found. 
) 

или

IF EXIST "flava.jpg" (
    REM Get current filesize 
    FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA 
    CALL ECHO %%_existingFileSize%% 
) ELSE (
    ECHO File not found. 
) 

или

set "_existingfilesize=" 
FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA 
if defined _existingfilesize (echo %_existingfilesize%) else (echo file not found) 

Вопрос заключается в том, что в пределах оператора блока (a parenthesised series of statements), блок вся анализируется и затем выполняется. Любой %var% в блоке будет заменен значением этой переменной на момент анализа блока - до того, как блок будет выполнен - ​​то же самое относится к FOR ... DO (block).

Следовательно, IF (something) else (somethingelse) будет выполнен с использованием значений %variables% в момент возникновения ошибки IF.

Два распространенный способ преодоления этого является: 1) использовать setlocal enabledelayedexpansion и использовать !var! вместо %var%, чтобы получить доступ к измененному значению var или 2) для вызова подпрограммы, чтобы выполнить дальнейшую обработку с использованием измененных значений.

Обратите внимание, что использование CALL ECHO %%var%% отображает измененное значение var. CALL ECHO %%errorlevel%% отображает, но, к сожалению, RESETS errorlevel.

Answer 2

Попробуйте распечатать файл из одного или нескольких файлов. Я сделал подпрограмму , что упростило запись сложных блоков кода. Если вам нужны два именованных файла, используйте точные файл значений.

@echo off 
set file=*.bat 
for %%A in (%file%) do call :DOIT %%A 
goto :END 

:DOIT 
echo %1 size is %~z1 
goto :EOF 

:END 
pause