Как я могу проверить исключения при использовании IOmniTaskControl/TOmniWorker?

Question

Я использую IOmniTaskControl/TOmniWorker для выполнения кода последовательности в конкретный поток. Я буду повторно использовать этот IOmniTaskControl для нескольких вызовов Invoke. Как проверить исключения, которые могли произойти во время Invoke? Это вопрос на вопрос/ответ: Waiting for Invoke to finish when using IOmniTaskControl/TOmniWorker.

Я проверил ExitCode и FatalException IOmniTaskControl, но они не установлены. Кажется, что IOmniTaskControl автоматически создаст новую задачу для каждого вызова Invoke, и исключение будет помещено в эту задачу, если это произойдет. Тем не менее, я не имею ссылки на эту задачу после завершения Invoke. Я использую TOmniWaitableValue для отметки, когда invoke завершает работу, но не ясно, что мне нужно сделать, чтобы сделать любое исключение, которое имело место для меня по возвращении из WaitFor (...).

Вот фрагмент структуры у меня есть:

interface 

type 
    TMyTaskProc = reference to procedure; 

    TMyTask = class 
    private 
    FWorker:  IOmniWorker; 
    FTaskControl: IOmniTaskControl; 
    FWaitable: IOmniWaitableValue; 
    public 
    constructor Create; 
    destructor Destroy; override; 

    procedure AwaitInvoke(Proc: TMyTaskProc); overload; 
    end; 

implementation 

type 
    TMyTaskWorker = class(TOmniWorker); 

constructor TMyTask.Create; 
begin 
    inherited; 

    FWorker := TMyTaskWorker.Create; 
    FTaskControl := CreateTask(FWorker).Run; 
    FWaitable := TOmniWaitableValue.Create; 
end; 

destructor TMyTask.Destroy; 
begin 
    FTaskControl.Terminate; 
    FTaskControl := nil; 

    FWaitable := nil; 

    inherited; 
end; 

procedure TMyTask.AwaitInvoke(Proc: TMyTaskProc); 
begin 
    FWaitable.Reset; 

    FTaskControl.Invoke(
    procedure 
    begin 
     try 
     Proc(); 
     finally 
     FWaitable.Signal; 
     end; 
    end 
); 

    FWaitable.WaitFor(INFINITE); 
end; 

Таким образом, в приведенном выше настройки, как я могу проверить после FWaitable.WaitFor (INFINITE) для каких-либо исключений, которые могли произойти во время Proc() вызов. Я хотел бы просто поднять его снова в тот момент в вызывающем потоке.

Answer 1

Вы должны поймать исключение в тот момент, когда вы вызываете Proc, а затем каким-то образом уведомляете вызывающего абонента об этой ситуации. Например:

FTaskControl.Invoke(
    procedure 
    var 
    return: TOmniValue; 
    begin 
    return := TOmniValue.Null; 
    try 
     try 
     Proc(); 
     except 
     return.AsException := AcquireExceptionObject; 
     end; 
    finally 
     FWaitable.Signal(return); 
    end; 
    end 
); 

FWaitable.WaitFor(INFINITE); 
if FWaitable.Value.IsException then begin 
    Writeln('Caught exception ' + FWaitable.Value.AsException.ClassName); 
    FWaitable.Value.AsException.Free; 
end;