Можно ли просто напечатать строку, которая была передана в макрос схемы?

Question

Я работаю над переводчиком языка в схеме guile и должен обрабатывать основной случай, когда вы пытаетесь преобразовать одно слово.

(define var 5) 
(translate var) 

Это должно вернуть строку var, а не число 5.
Как это сделать с использованием макросов схемы R5RS (стиль define-syntax)?

Редактировать:
Я переводил с Схемы в Coffeescript.

Answer 1

(define-syntax translate 
    (syntax-rules() 
    [(_ v) 'v])) 

И если вы хотите строку: компилятор

(define-syntax translate 
    (syntax-rules() 
    [(_ v) (symbol->string 'v)])) 

Будет надеяться хитростью является достаточно умен, чтобы сложить полученное выражение, так что по существу становится постоянной строкой.

Answer 2

С syntax-case и его охранник поддержка:

(define-syntax translate 
    (lambda (stx) 
    (syntax-case stx() 
     [(_ v) (identifier? #'v) 
     #'(symbol->string 'v)] 
     [(_ v) (number? (syntax-e #'v)) 
     #'(number->string v)]))) 

(. Я использовал квадратные скобки для облегчения сравнения с ответом Эли, однако, это не мой обычный стиль ;-))

Но если вы используете syntax-case, то вы можете точно также сделать преобразование на уровне синтаксиса, а не производить код, который делает это во время выполнения:

(define-syntax translate 
    (lambda (stx) 
    (syntax-case stx() 
     [(_ v) (identifier? #'v) 
     (datum->syntax stx (symbol->string (syntax->datum #'v)))] 
     [(_ v) (number? (syntax-e #'v)) 
     (datum->syntax stx (number->string (syntax->datum #'v)))]))) 

Главное здесь в том, что код макроса теперь обычная схема, например, вы могли бы абстрагировать общие части в качестве помощника:

(define-syntax translate 
    (lambda (stx) 
    (define (rewrap convert x) 
     (datum->syntax stx (convert (syntax->datum x)))) 
    (syntax-case stx() 
     [(_ v) (identifier? #'v) (rewrap symbol->string #'v)] 
     [(_ v) (number? (syntax-e #'v)) (rewrap number->string #'v)]))) 

В том же ключе, если этот макрос так просто, то никакой реальной потребность в syntax-case, кроме вытаскивания подвыражению:

(define-syntax translate 
    (lambda (stx) 
    (syntax-case stx() 
     [(_ v) (let ([d (syntax->datum #'v)]) 
       (datum->syntax 
       stx 
       ((cond [(number? d) number->string] 
         [(symbol? d) symbol->string]) 
       d)))]))) 

Примечания, кстати, что нет никакой магии в syntax-case - и в случае этой простой модели, вы могли бы просто вытащить значение себя:

(define-syntax translate 
    (lambda (stx) 
    (let ([d (cadr (syntax->datum #'v))]) 
     (datum->syntax 
     stx 
     ((cond [(number? d) number->string] 
       [(symbol? d) symbol->string]) 
     d))))) 

Существует несколько шаблонного материала, который syntax-case делает, что эта последнюю версия проигрывает:

• Если вы используете макрос неожиданным образом, как (translate) то эта версия будет выдавать ошибку о cadr вместо более понятного синтаксиса ошибка

• Аналогично, если вы используете (translate 1 2), тогда эта версия просто молча игнорирует 2 вместо ошибки.

• И если он используется с чем-то, что не является ни идентификатор, ни число (например, (translate (+ 1 2))), то это будет зависеть от неопределенного значения, cond возвращается, а не бросать ошибку синтаксиса.

Answer 3

других ответов полезен уже достаточно, но я думал, что просто указать на то, что можно обобщить эту технику в очень удобном виде: макросы для распечатки выражения и их результатов для отладки:

(define-syntax log-expr 
    (syntax-rules() 
    ((_ expr) 
    (let ((result expr)) 
     (write (quote expr)) 
     (display " evaluates to ") 
     (write result) 
     (newline) 
     result))))